How to make numbers not repeat from a specific list - vb.net

Question

I have been banging my head against the wall trying to figure out how to make numbers not repeat from a specific list that I have created. Can someone please help? Once a number is chosen I dont want it to be chosen again. Seems like numbers.Remove(number) isnt working
Private Sub GetMoneyRand()
If randomLog.Count = numberList.Count Then
MsgBox("No more number for random")
Return
End If
For i As Integer = 1 To 100
Dim rndDummy As Integer = CInt(numMax.Value * Rnd())
lblRandomNumber.Text = rndDummy
Threading.Thread.Sleep(30)
Application.DoEvents()
Next
Randomize()
Dim r As New Random
Dim numbers As New List(Of Integer)
numbers.AddRange(New Integer() {1, 16, 31, 46, 61, 10, 15, 14, 75, 33, 11, 19, 25, 44, 50, 72, 2, 44, 20, 30})
Dim number As Integer = numbers(r.Next(0, numbers.Count))
For x As Integer = 1 To 20
numbers.Remove(number)
Next
randomLog.Add(number)
lblRandomNumber.Text = number
numberList(number).BackColor = Color.LightBlue

Answer 1

Please turn on Option Strict. This is a 2 part process. First for the current project - In Solution Explorer double click My Project. Choose Compile on the left. In the Option Strict drop-down select ON. Second for future projects - Go to the Tools Menu -> Options -> Projects and Solutions -> VB Defaults. In the Option Strict drop-down select ON. This will save you from bugs at runtime.
To create a list with unique random numbers use the .Contains method of List(of T) before adding the new random to the list.
Private numbers As New List(Of Integer) From {1, 16, 31, 46, 61, 10, 15, 14, 75, 33, 11, 19, 25, 44, 50, 72, 2, 44, 20, 30}
Private r As New Random
Private Sub AddRandomsToList()
Dim i = r.Next(0, 21)
If numbers.Contains(i) Then
MessageBox.Show("Sorry that number is already in the list. Try Again.")
Else
numbers.Add(i)
End If
End Sub
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
AddRandomsToList()
End Sub
To remove duplicates from an existing list use the .Distinct extension method. It will return a new list of unique elements when you call .ToList
Private numbers As New List(Of Integer) From {1, 16, 1, 46, 61, 16, 15, 14, 61, 46, 11, 19, 25, 46, 50, 50, 2, 44, 20, 30}
Private r As New Random
Private Sub RemoveDuplicate()
Dim UniqueNumbers = numbers.Distinct().ToList
For Each i In UniqueNumbers
Debug.Print(i.ToString)
Next
End Sub

Answer 2

You should be using a stack or a queue. They both remove items as they are used.
Private numbers As Integer() = {1, 16, 31, 46, 61, 10, 15, 14, 75, 33, 11, 19, 25, 44, 50, 72, 2, 44, 20, 30}
Private rng As New Random
Private Sub OutputNumbersInRandomOrder()
Dim randomisedNumbers As New Queue(Of Integer)(numbers.OrderBy(Function(n) rng.NextDouble()))
Do Until randomisedNumbers.Count = 0
Dim number = randomisedNumbers.Dequeue()
Console.WriteLine(number)
Loop
End Sub
Each time you call Dequeue, the first number is removed from the list and returned. You can do this as many times as you like, creating a new queue each time the previous one is empty, e.g.
Private numbers As Integer() = {1, 16, 31, 46, 61, 10, 15, 14, 75, 33, 11, 19, 25, 44, 50, 72, 2, 44, 20, 30}
Private randomisedNumbers As Queue(Of Integer)
Private rng As New Random
Private Function GetRandomNumber() As Integer
If randomisedNumbers Is Nothing OrElse randomisedNumbers.Count = 0 Then
randomisedNumbers = New Queue(Of Integer)(numbers.OrderBy(Function(n) rng.NextDouble()))
End If
Return randomisedNumbers.Dequeue()
End Function
You can do the same thing with a Stack(Of Integer) and calling Pop. The only difference is that a stack takes items from the other end - LIFO instead of FIFO. As the items are randomised and all added at the same time, there's really no difference in the outcome, especially given that calling OrderByDescending would reverse the outcomes of the two types anyway. To illustrate:
Dim numbers = {1, 2, 3, 4, 5}
Dim q1 As New Queue(Of Integer)(numbers)
Dim s1 As New Stack(Of Integer)(numbers)
Console.WriteLine("q1:")
Do Until q1.Count = 0
Console.WriteLine(q1.Dequeue())
Loop
Console.WriteLine("s1:")
Do Until s1.Count = 0
Console.WriteLine(s1.Pop())
Loop
Array.Reverse(numbers)
Dim q2 As New Queue(Of Integer)(numbers)
Dim s2 As New Stack(Of Integer)(numbers)
Console.WriteLine("q2:")
Do Until q2.Count = 0
Console.WriteLine(q2.Dequeue())
Loop
Console.WriteLine("s2:")
Do Until s2.Count = 0
Console.WriteLine(s2.Pop())
Loop
Output:
q1:
1
2
3
4
5
s1:
5
4
3
2
1
q2:
5
4
3
2
1
s2:
1
2
3
4
5