How can I represent a more "complex" constructor in ABAP? - abap

Question

I have some Java code which i want to transfer into ABAP. I struggle with the attributes and constructor declaration/implementation.
How can I represent the folllowing Java code in ABAP?
class Node {
private String data;
private Node[] children = new Node[0];
private Node parent = null;
public Node(String data) {
this(data, null);
}
public Node(String data, Node child) {
this.data = data;
if (child != null) {
this.addChild(child);
}
}
}

Answer 1

This is as near as you can get:
CLASS node DEFINITION
PUBLIC CREATE PUBLIC.
PUBLIC SECTION.
METHODS constructor
IMPORTING
data TYPE string
child TYPE REF TO node OPTIONAL.
PRIVATE SECTION.
DATA data TYPE string.
DATA children TYPE STANDARD TABLE
OF REF TO node WITH EMPTY KEY.
DATA parent TYPE REF TO node.
ENDCLASS.
CLASS node IMPLEMENTATION.
METHOD constructor.
me->data = data.
IF child IS BOUND.
INSERT child INTO TABLE children.
ENDIF.
ENDMETHOD.
ENDCLASS.
ABAP doesn’t support overloading, meaning you cannot have multiple variants of a method with different sets of input parameters.

Answer 2

You Cant do "exactly" what you want. ABAP is not fully polymorphic like most OO languages.
You cant have 2 constructors with different signatures.
You can have a constructor with optional parameters and get a very similar result.
Have a go and see what you manage and post again.

Answer 3

Let me throw in another option, if you have multiple variants for construction and want to prevent optional parameters:
CLASS node DEFINITION
PUBLIC CREATE PRIVATE.
PUBLIC SECTION.
CLASS-METHODS create_with_data
IMPORTING
data TYPE string
RETURNING
VALUE(result) TYPE REF TO node.
CLASS-METHODS create_with_data_and_child
IMPORTING
data TYPE string
child TYPE REF TO node
RETURNING
VALUE(result) TYPE REF TO node.
PRIVATE SECTION.
DATA data TYPE string.
DATA children TYPE STANDARD TABLE
OF REF TO node WITH EMPTY KEY.
DATA parent TYPE REF TO node.
METHODS constructor
IMPORTING
data TYPE string
child TYPE REF TO node OPTIONAL.
ENDCLASS.
CLASS node IMPLEMENTATION.
METHOD create_with_data.
result = NEW #( data = data ).
ENDMETHOD.
METHOD create_with_data_and_child.
result = NEW #(
data = data
child = child ).
ENDMETHOD.
METHOD constructor.
me->data = data.
IF child IS BOUND.
INSERT child INTO TABLE children.
ENDIF.
ENDMETHOD.
ENDCLASS.