Converting ABAP 740 syntax to 700 - VALUE & LOOP AT ... GROUP BY - abap

Question

I found a demo program for the tree salv online that I wanted to use, but since it uses 740 syntax, I have to convert it first. Which is also a good opportunity to learn more about the new syntax.
I already did almost all of it, but am having trouble with VALUE. Reading this wiki entry, among others, couldn't help me.
Original code in 740:
" Treenodes einfügen
LOOP AT it_spfli ASSIGNING FIELD-SYMBOL(<c>) GROUP BY <c>-carrid.
DATA(it_cp) = VALUE ty_it_spfli( FOR <cp> IN GROUP <c> ( <cp> ) ).
DATA(o_parent) = o_tree->get_nodes( )->add_node( related_node = ''
relationship = cl_gui_column_tree=>relat_last_child
collapsed_icon = CONV #( icon_closed_folder )
expanded_icon = CONV #( icon_open_folder )
row_style = if_salv_c_tree_style=>intensified
text = CONV #( <c>-carrid ) ).
IF lines( it_cp ) > 1.
o_parent->get_item( 'CARRID' )->set_type( if_salv_c_item_type=>button ).
o_parent->get_item( 'CARRID' )->set_value( 'all' ).
ENDIF.
LOOP AT GROUP <c> ASSIGNING FIELD-SYMBOL(<f>).
DATA(o_carrid) = o_tree->get_nodes( )->add_node( related_node = o_parent->get_key( )
relationship = cl_gui_column_tree=>relat_last_child
data_row = <f>
row_style = if_salv_c_tree_style=>intensified
text = CONV #( <f>-connid ) ).
o_carrid->get_item( 'CARRID' )->set_type( if_salv_c_item_type=>checkbox ).
o_carrid->get_item( 'CARRID' )->set_editable( abap_true ).
ENDLOOP.
ENDLOOP.
New code in 700, except for line with VALUE:
" new variables added to convert code to 700
DATA: o_nodes TYPE REF TO cl_salv_nodes,
o_parent TYPE REF TO cl_salv_node,
o_carrid TYPE REF TO cl_salv_node,
o_item TYPE REF TO cl_salv_item,
o_key TYPE lvc_nkey.
DATA: h_collapsed_icon TYPE salv_de_tree_image VALUE 'icon_closed_folder',
h_expanded_icon TYPE salv_de_tree_image VALUE 'icon_open_folder',
h_text_carrid TYPE lvc_value.
DATA: it_cp TYPE STANDARD TABLE OF ty_it_spfli.
SORT it_spfli BY carrid.
" Treenodes einfügen
LOOP AT it_spfli ASSIGNING <c>.
AT NEW carrid.
it_cp = value TY_IT_SPFLI( for <CP> in GROUP <c> ( <CP> ) ). <--- Here
o_nodes = o_tree->get_nodes( ).
h_text_carrid = <c>-carrid.
o_parent = o_nodes->add_node( related_node = ''
relationship = cl_gui_column_tree=>relat_last_child
collapsed_icon = h_collapsed_icon
expanded_icon = h_expanded_icon
row_style = if_salv_c_tree_style=>intensified
text = h_text_carrid ).
IF LINES( it_cp ) > 1.
o_item = o_parent->get_item( 'CARRID' ).
o_item->set_type( if_salv_c_item_type=>button ).
o_item->set_value( 'all' ).
ENDIF.
ENDAT.
o_key = o_parent->get_key( ).
o_carrid = o_nodes->add_node( related_node = o_key
relationship = cl_gui_column_tree=>relat_last_child
data_row = <c>
row_style = if_salv_c_tree_style=>intensified
text = h_text_carrid ).
o_item = o_parent->get_item( 'CARRID' ).
o_item->set_type( if_salv_c_item_type=>checkbox ).
o_item->set_editable( abap_true ).
ENDLOOP.
My questions are now:
Did I convert the LOOP AT ... GROUP BY correctly by using AT NEW?
How do I convert the line with VALUE?
Thank you in advance for your help.

Answer 1

You can't do the conversion the way you did. The outer loop of the original code grouping by the CARRID is not exactly like AT NEW, because it generates a temporary group table which then you can use everywhere. Without it, you should generate the group in advance.
I didn't verify the code, but to simulate the GROUP BY and then make the rest of the conversion easy without having to rewrite too much, I would create a nested table for each CARRID from the original:
DATA: BEGIN OF ls_spfli_carrid_group,
carrid TYPE carrid,
flights TYPE ty_it_spfli,
END OF ls_spfli_carrid_group,
lt_spfli_carrid_group LIKE STANDARD TABLE OF ls_spfli_carrid_group.
SORT it_spfli BY carrid.
LOOP AT it_spfli INTO ls_spfli.
AT NEW carrid.
it_spfli
ls_spfli_carrid_group-carrid = ls_spfli-carrid.
REFRESH ls_spfli_carrid_group-flights.
APPEND ls_spfli_carrid_group TO lt_spfli_carrid_group.
ENDAT.
APPEND ls_spfli TO ls_spfli_carrid_group-flights.
ENDLOOP.
LOOP AT lt_spfli_carrid_group INTO ls_spfli_carrid_group.
it_cp = ls_spfli_carrid_group-flights.
...
LOOP AT ls_spfli_carrid_group-flights INTO ls_flight. "Should be like the LOOP AT GROUP
ENDLOOP.
ENDLOOP.

Answer 2

In fact, you are asking what means the line with "FOR ... IN GROUP":
TYPES: ty_it_spfli TYPE STANDARD TABLE OF spfli WITH DEFAULT KEY.
DATA it_spfli TYPE ty_it_spfli.
LOOP AT it_spfli ASSIGNING FIELD-SYMBOL(<c>) GROUP BY <c>-carrid.
DATA(it_cp) = VALUE ty_it_spfli( FOR <cp> IN GROUP <c> ( <cp> ) ).
...
ENDLOOP.
First of all, the outer loop with "GROUP BY" iterates on the distinct values of CARRID component. For example, the internal table it_spfli may have 100 lines, but there are only 10 distinct CARRID values, so it will iterate 10 times.
The inner "value construction" FOR <cp> IN GROUP <c> does a loop at the "members" of the "group" of lines <c>, where the "members" are the lines of it_spfli which correspond to the current group (those lines which correspond to the value of CARRID of the current group), and at each iteration the line ( <cp> ) is appended to the variable it_cp.
This line:
DATA(it_cp) = VALUE ty_it_spfli( FOR <cp> IN GROUP <c> ( <cp> ) ).
is equivalent to the following syntax with LOOP AT GROUP, which is valid only from 7.40 too, but it should be more clear to you, and you can convert it in 7.0 more intuitively:
DATA(it_cp) = VALUE ty_it_spfli( ). " initialization (empty internal table)
LOOP AT GROUP <c> ASSIGNING FIELD-SYMBOL(<cp>).
INSERT <cp> INTO TABLE it_cp.
ENDLOOP.

Answer 3

Thank you Sandra and RaTiO for your help.
Now that I understood what is supposed to happen, I have the following two solutions (one of them being the one from RaTiO).
(What is supposed to happen: The VALUE command was supposed to fill another itab with those lines of the looping table, which contain the current CARRID. Then depending on the amount of lines, you could see if the node will have children and thus need to be an expanding button.)
So the solution I thought of myself was to fill a copy of the table inside the LOOP and delete those entries that do not contain the current CARRID.
DATA: it_copy_spfli TYPE ty_it_spfli.
...
SORT it_spfli BY carrid.
LOOP AT it_spfli ASSIGNING <c>.
AT NEW carrid.
REFRESH it_copy_spfli.
it_copy_spfli = it_spfli.
DELETE it_copy_spfli WHERE carrid <> <c>-carrid.
...
IF LINES( it_copy_spfli ) > 1.
...
ENDIF.
ENDAT.
...
ENDLOOP.
Then there's RaTiO's solution, creating a nested table to LOOP over instead.
DATA: it_copy_spfli TYPE ty_it_spfli.
DATA: BEGIN OF ls_spfli_carrid_group,
carrid TYPE s_carr_id,
flights TYPE ty_it_spfli,
END OF ls_spfli_carrid_group.
DATA: ls_spfli TYPE spfli,
ls_flight TYPE spfli,
lt_spfli_carrid_group LIKE STANDARD TABLE OF ls_spfli_carrid_group.
SORT it_spfli BY carrid.
LOOP AT it_spfli INTO ls_spfli.
APPEND ls_spfli TO ls_spfli_carrid_group-flights.
AT END OF carrid.
ls_spfli_carrid_group-carrid = ls_spfli-carrid.
APPEND ls_spfli_carrid_group TO lt_spfli_carrid_group.
REFRESH ls_spfli_carrid_group-flights.
ENDAT.
ENDLOOP.
LOOP AT lt_spfli_carrid_group INTO ls_spfli_carrid_group.
REFRESH it_copy_spfli.
it_copy_spfli = ls_spfli_carrid_group-flights.
...
h_text_carrid = ls_spfli_carrid_group-carrid.
...
IF LINES( it_copy_spfli ) > 1.
...
ENDIF.
LOOP AT ls_spfli_carrid_group-flights INTO ls_flight.
...
o_carrid = o_nodes->add_node( ...
data_row = ls_flight
... ).
...
ENDLOOP.
ENDLOOP.
Then I adapted it to use FIELD-SYMBOLS instead.
DATA: it_copy_spfli TYPE ty_it_spfli.
TYPES: BEGIN OF ty_spfli_carrid_group,
carrid TYPE s_carr_id,
flights TYPE ty_it_spfli,
END OF ty_spfli_carrid_group.
DATA: lt_spfli_carrid_group TYPE STANDARD TABLE OF ty_spfli_carrid_group.
FIELD-SYMBOLS: <spfli> TYPE spfli,
<flight> TYPE spfli,
<spfli_carrid_group> TYPE ty_spfli_carrid_group.
SORT it_spfli BY carrid.
LOOP AT it_spfli ASSIGNING <spfli>.
AT NEW carrid.
APPEND INITIAL LINE TO lt_spfli_carrid_group ASSIGNING <spfli_carrid_group>.
ENDAT.
APPEND <spfli> TO <spfli_carrid_group>-flights.
AT END OF carrid.
<spfli_carrid_group>-carrid = <spfli>-carrid.
ENDAT.
ENDLOOP.
LOOP AT lt_spfli_carrid_group ASSIGNING <spfli_carrid_group>.
...
LOOP AT <spfli_carrid_group>-flights ASSIGNING <flight>.
...
ENDLOOP.
ENDLOOP.
All the solutions worked as expected. Comparing the runtime, the last one was the fastest, but they were very very close. So I decided to use mine, since it is only a couple lines, while RaTiO's requires another LOOP.
Thank you again =)