How to insert from file by SlideID - vba

Question

I have a PowerPoint slide library and numerous presentations. I want to use a macro (VBA) to find a particular slide by SlideID (or some other marker, tag) in all open presentations, delete that slide, then insert in the same location an updated slide from my Slide Library.
This step works:
ActivePresentation.Slides.FindBySlideID(1296).Delete
where do I go from there to InsertFromFile a specific slide with its own SlideID?
Thanks.

Answer 1

The following macro will first retrieve the slide index for the specified slide ID from the specified presentation, and then insert the slide into the active presentation.
Option Explicit
Sub InsertSlideFromFileBySlideID()
Dim sourcePresentation As Presentation
Dim sourceFile As String
Dim sourceSlideID As Long
Dim sourceSlideIndex As Long
sourceFile = "c:\users\domenic\desktop\sample.pptx" 'change the path and filename accordingly
sourceSlideID = 256 'change the ID accordingly
Set sourcePresentation = Application.Presentations.Open(FileName:=sourceFile, ReadOnly:=msoTrue)
sourceSlideIndex = sourcePresentation.Slides.FindBySlideID(sourceSlideID).slideIndex
sourcePresentation.Close
'Insert the slide from the source file that has the specified slide index number at the end of the active presentation
With ActivePresentation
.Slides.InsertFromFile FileName:=sourceFile, Index:=.Slides.Count, SlideStart:=sourceSlideIndex, SlideEnd:=sourceSlideIndex
End With
End Sub
EDIT
The following macro will copy multiple slides, by SlideID, from the specified open presentation to the active presentation.
Option Explicit
Sub CopySlidesBySlideID()
Dim sourcePresentation As Presentation
On Error Resume Next
Set sourcePresentation = Application.Presentations("sample.pptx") 'change the name accordingly
If sourcePresentation Is Nothing Then
MsgBox "Source presentation not found!", vbExclamation
Exit Sub
End If
On Error GoTo 0
Dim vSlideIDs As Variant
vSlideIDs = Array(256, 260, 258) 'change the slide IDs accordingly
Dim i As Long
For i = LBound(vSlideIDs) To UBound(vSlideIDs)
sourcePresentation.Slides.FindBySlideID(vSlideIDs(i)).Copy
ActivePresentation.Slides.Paste
Next i
End Sub