Opening a Report based on two date values on a form if they exist - vba

Question

I have a form (frmReports) that has two unbound textboxes which are used to enter dates. One is FROM, one is TO.
These are used to filter out a report (rptAllCommissions). If there are values in the textboxes, it filters. If there aren't, or if there's one date and not both, it creates a WHERE statement for opening the report. Here is the code:
Private Sub cmdCommissions_Click()
Dim strDateFrom As String
Dim strDateTo As String
Dim strWhere As String
Const strcJetDate = "\#mm\/dd\/yyyy\#"
strDateFrom = "[ClosingDate]"
If IsDate(Me.txtFrom) Then
strWhere = "(" & strDateFrom & " >=" & Format(Me.txtFrom, strcJetDate) & ")"
End If
If IsDate(Me.txtTo) Then
If strWhere <> vbNullString Then
strWhere = strWhere & " AND "
End If
strWhere = strWhere & "(" & strDateFrom & " <= " & Format(Me.txtTo + 1, strcJetDate) & ")"
End If
If CurrentProject.AllReports("rptAllCommissions").IsLoaded Then
DoCmd.Close acReport, "rptAllCommissions"
End If
Debug.Print strWhere
DoCmd.OpenReport "rptAllCommissions", acViewReport, strWhere
Exit_Handler:
Exit Sub
Err_Handler:
If Err.Number <> 2501 Then
MsgBox "Error" & Err.Number & ": " & Err.Description, vbExclamation, "Cannot Open Report!"
End If
Resume Exit_Handler
End Sub
The problem I'm having is no matter what I try, the report never filters the records based on the WHERE statement created by the above routine. Trying debugging, it outputs:
If two dates are entered: ([ClosingDate] >=#04/01/2019#) AND ([ClosingDate] <= #05/25/2019#)
If one date is entered: ([ClosingDate] >=#05/13/2019#)
That seems right to me, but it's not filtering. What the heck am I doing wrong?
EDIT: I should give credit the person who wrote the original routine, but I can't for the life of me find where I got it. Sorry! But whoever it was that originally wrote the routine, THANKS!

Answer 1

The WhereCondition should be the 4th argument in the OpenReport method. You have it in the FilterName argument's spot.
OpenReport