Search Query Works First Time but subsequent runs get run-time error 3075 extra ) in query expression - vba

Question

I have gone through all previous questions asked and even tried the solutions but to no avail so here's my dilemna. I have used a search query from Allenbrowne which was initially great. However, I wanted to add to the search criteria which again I have done and when searching for the first time I got the results I was looking for. I now use a different code to remove all the search criteria and to unfilter the form (split form). Again everything works. Now I want to search again either using the same of different parameters and this time I get the run-time error 3075 stating that I have an extra ) in the query expression. I have even looked up the query to see where this extra ) is but to no avail. The code is as follows and it errors on Me.Filter = strWhere. I have also provided the reset filter when clearing the search screen and wanting to start a new search. Any help would really be appreciated.
Option Compare Database
Option Explicit
Private Sub cmdFilter_Click()
Dim strWhere As String 'The criteria string.
Dim lngLen As Long 'Length of the criteria string to append to.
'***********************************************************************
'Look at each search box, and build up the criteria string from the non-blank ones.
'***********************************************************************
If Not IsNull(Me.txtCustID) Then
strWhere = strWhere & "([Customer_ID] = " & Me.txtCustID & ") AND "
End If
If Not IsNull(Me.txtJobID) Then
strWhere = strWhere & "([Job_ID] = " & Me.txtJobID & ") AND "
End If
If Not IsNull(Me.txtName) Then
strWhere = strWhere & "([Name] Like ""*" & Me.txtName & "*"") AND "
End If
If Not IsNull(Me.TxtPostcode) Then
strWhere = strWhere & "([Postcode] = ""*" & Me.TxtPostcode & "*"") AND "
End If
If Not IsNull(Me.txtCompany) Then
strWhere = strWhere & "([CompanyName] Like ""*" & Me.txtCompany & "*"") AND "
End If
If Not IsNull(Me.txtLocation) Then
strWhere = strWhere & "([Location] Like ""*" & Me.txtLocation & "*"") AND "
End If
If Not IsNull(Me.CboStatus) Then
strWhere = strWhere & "([Status] = " & Me.CboStatus & ") AND "
End If
If Not IsNull(Me.CboSource) Then
strWhere = strWhere & "([EnquirySource] = " & Me.CboSource & ") AND "
End If
'See if the string has more than 4 characters (a trailng " AND ") to remove.
lngLen = Len(strWhere) - 4
If lngLen <= 0 Then 'Nah: there was nothing in the string.
MsgBox "No criteria", vbInformation, "Nothing to do."
Else 'Yep: there is something there, so remove the " AND " at the end.
strWhere = Left$(strWhere, lngLen)
'For debugging, remove the leading quote on the next line. Prints to Immediate Window (Ctrl+G).
Debug.Print strWhere
'Finally, apply the string as the form's Filter.
Me.Filter = strWhere
Me.FilterOn = True
End If
End Sub
Private Sub cmdReset_Click()
'Purpose: Clear all the search boxes in the Form Header, and show all records again.
Dim ctl As Control
'Clear all the controls in the Form Header section.
For Each ctl In Me.Section(acHeader).Controls
Select Case ctl.ControlType
Case acTextBox, acComboBox
ctl.Value = ""
Case acCheckBox
ctl.Value = False
End Select
Next
'Remove the form's filter.
Me.FilterOn = False
End Sub

Answer 1

See this ctl.Value = "" in cmdReset_Click()? I would guess that when you clear the controls, one of them is ending up a zero-length string, but your test in building the filter is for null, not zero-length strings, so something, most likely one of the numerics, is ending up somefield=<blank>. Try:
ctl.Value = Null
As an aside, there is no point in using equals with a wild card:
strWhere = strWhere & "([Postcode] = ""*" & Me.TxtPostcode & "*"") AND "
Should be:
strWhere = strWhere & "([Postcode] Like ""*" & Me.TxtPostcode & "*"") AND "
Or
strWhere = strWhere & "([Postcode] = """ & Me.TxtPostcode & """) AND "