How to transfer data from parallel arrays into a textbox? - vb.net

Question

I'm trying to write a program that splits data from a text file into parallel arrays and then writes the content of each array in a textbox. The text file is something like this:
Title1, Genre1, Director1,
Title2, Genre2, Director2,
Title3, Genre3, Director3,
Imports System.IO
Public Class Form1
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim sr As New StreamReader("MovieData.txt")
Dim movieTitles(9), genre(9), directors(9), itemsRead() As String
Dim i As Integer = 0
Do Until sr.Peek = -1
itemsRead = sr.ReadLine.Split(",")
movieTitles(i) = itemsRead(0)
genre(i) = itemsRead(1)
directors(i) = itemsRead(2)
TextBox1.Text = movieTitles(i).PadRight(20) & genre(i).PadRight(20) & directors(i)
i += 1
Loop
sr.Dispose()
End Sub
End Class
When I click on the button, the textbox shows only:
Title3 Genre3 Director3
How can I fix this?

Answer 1

If you want your data to line up nicely, use a DataGridView. The extra functionality of a StreamReader is not necessary when you only need to pull data from a text file.
Now that classes and there properties are so easy you really don't need parallel arrays.
I added a custom constructor to the class so you can create a new instance and set all the properties in one line.
The list of Movie can be used as a data source for the grid. No need to set up columns.
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim Movies As New List(Of Movie)
Dim lines = File.ReadAllLines("MovieData.txt")
For Each line In lines
Dim MovieProperties = line.Split(","c)
Dim M As New Movie(MovieProperties(0).Trim, MovieProperties(1).Trim, MovieProperties(2).Trim)
Movies.Add(M)
Next
DataGridView1.DataSource = Movies
End Sub
Public Class Movie
Public Property Title As String
Public Property Genre As String
Public Property Director As String
Public Sub New(T As String, G As String, D As String)
Title = T
Genre = G
Director = D
End Sub
End Class
EDIT as per OP comment
'**EDIT** Move the declaration of Movies to Form level
Private Movies As New List(Of Movie)
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
'**EDIT** Remove local declaration of Movies
Dim lines = File.ReadAllLines("MovieData.txt")
For Each line In lines
Dim MovieProperties = line.Split(","c)
Dim M As New Movie(MovieProperties(0).Trim, MovieProperties(1).Trim, MovieProperties(2).Trim)
Movies.Add(M)
Next
DataGridView1.DataSource = Movies
'To return the movies by Director, I strongly suggest you fill a list box with the
'director names so spelling errors won't frustate users
ListBox1.DataSource = GetUniqueDirectors()
End Sub
Private Function GetUniqueDirectors() As List(Of String)
'A bit of Linq using Distinct so we don't get duplicate listing of director names.
Dim Directors = ((From m In Movies
Order By m.Director
Select m.Director).Distinct()).ToList
Return Directors
End Function
Private Function GetMoviesByDirector(sDirector As String) As List(Of String)
'A little Linq magic to get the movies for selected director
Dim DirectorsMovies = (From s In Movies
Where s.Director = sDirector
Order By s.Title
Select s.Title).ToList
Return DirectorsMovies
End Function
Public Class Movie
Public Property Title As String
Public Property Genre As String
Public Property Director As String
Public Sub New(T As String, G As String, D As String)
Title = T
Genre = G
Director = D
End Sub
End Class
Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
If ListBox1.SelectedIndex = -1 Then
MessageBox.Show("Please select a Director from the list.")
Return
End If
ListBox2.DataSource = Nothing
ListBox2.Items.Clear()
ListBox2.DataSource = GetMoviesByDirector(ListBox1.SelectedItem.ToString)
End Sub

Answer 2

It is done, just replace the code of the TextBox1.Text line like this one:
TextBox1.Text += movieTitles(i).PadRight(20) & genre(i).PadRight(20) & directors(i) & vbNewLine
I hope this answers your question bro,
^_^