If statement in code to populate form - vba

Question

I have two sheets in a workbook. One contains a form, and the other contains data to populate the form with. I was able to write a small macro which successfully loops and populates the cell, Job Title, in Range("B16:I16") with the information in Column A from Data.
I'm trying to write an If statement within VBA that would populate the cell, Employee Work Location (Building), in Range("D14:H14") depending on the text in Job Title.
I wrote something out, but it doesn't seem to work. I get a mismatch error. May I ask for help with this please?
Thank you!
Sub FormPopulate_Click()
Dim i As Integer
Dim Building_Location as String
For i = 2 To 3
Sheets("Data").Select
Range("A" & CStr(i)).Select
ThisFile = Range("A" & CStr(i))
Selection.Copy
Sheets("Form").Select
Range("B16:I16").Select
ActiveSheet.Paste
Sheets("Form").Select
If Worksheets("Form").Range("B16:I16") = "Coordinator" Then
Building_Location = "East Quad"
Else
Building_Location =""
End If
Sheets("Form").Range("D14:H14").Value = Building_Location
Next i
End Sub

Answer 1

The main issue is you can't check multiple cells' values at once. You're trying this with ...Range("B16:I16") = "Coordinator". Instead, use something like COUNTIF().
Sub FormPopulate_Click()
Dim i As Long
Dim Building_Location As String
Dim dataWS As Worksheet, formWS As Worksheet
Dim thisFile As Range, destRange As Range
Set dataWS = Sheets("Data")
Set formWS = Sheets("Form")
For i = 2 To 3
Set thisFile = dataWS.Range("A" & i)
Set destRange = formWS.Range("B16:I16")
thisFile.Copy destRange
If WorksheetFunction.CountIf(formWS.Range("B16:I16"), "Coordinator") = destRange.Cells.Count Then
Building_Location = "East Quad"
Else
Building_Location = ""
End If
formWS.Range("D14:H14").Value = Building_Location
Next i
End Sub
Another note, you're going to overwrite the data in formWS.Range("B16:I16")in each iteration. Is that okay?

Answer 2

This part of the code:
Selection.Copy
Sheets("Form").Select
Range("B16:I16").Select
ActiveSheet.Paste
refers to cell data already copied, but here is being pasted to a range?? This is not (really) a range as it is a merged cell, so the reference should be B16 or B16:B16
Similarly later,
If Worksheets("Form").Range("B16:I16") = "Coordinator" Then ... should also only reference the single cell, as above.
Good luck.