VBA - Overflow Error only when using property of custom object - vba

Question

I'm trying to create a Player object that holds a Long property Wealth that must be assigned to a cell in Excel, but I get the Overflow runtime error only when the last line references newPlayer.Wealth and not when the value is set to a fixed number greater than the max integer. Here is the code:
For i = 68 To (67 + numPlayers)
Dim newPlayer As New Player
newPlayer.Wealth = CLng(40000)
newPlayer.Number = i - 67
Range(Chr(i) & "2").Value = "Player " & CStr(newPlayer.Number)
Range(Chr(i) & "3").Value = newPlayer.Wealth
Next
This works, however:
Range(Chr(i) & "3").Value = CLng(40000)
I tried to clear formatting from the cell that I'm specifying but I still have problems. What is the reason for this? Here is also my class properties:
Private pNumber As Integer
Private pProperties As New Collection
Private pWealth As Long
Property Get Number() As Integer
Number = pNumber
End Property
Property Let Number(pNum As Integer)
pNumber = pNum
End Property
Property Get Properties() As Collection
Properties = pProperties
End Property
Property Get Wealth() As Long
Number = pWealth
End Property
Property Let Wealth(w As Long)
pWealth = w
End Property
Public Sub addProperty(property As PropertyUnit)
pProperties.Add (property)
End Sub

Answer 1

Modify your class definition.
This appears wrong. Beyond the copy/paste from Get Number() error, shoving a 40K long into a signed integer is going to overflow.
Private pNumber As Integer
Private pWealth As Long
...
Property Get Wealth() As Long
Number = pWealth
End Property
Change to something like,
...
Private pWealth As Long
Property Get Wealth() As Long
Wealth= pWealth
End Property
Property Let Wealth(Value As Long)
pWealth = Value
End Property

Answer 2

As Jeeped pointed out Property Get Wealth() needs to be modified like this:
Property Get Wealth() As Long
Wealth = pWealth
End Property
A couple of other points.
There is no reason to cast the number to string for the address concatenations. The VBA will do that automatically. Range(Chr(i) & "2").Value and Range(Chr(i) & 2).Value are effectively the same.
There is no reason to cast a number into long. CLng(40000) or 40000 will work.
Dim newPlayer As New Player inside a loop will only create a single instance of the Player class. Declare newPlayer outside of the loop and use Set newPlayer = New Player inside the loop to create more instances of newPlayer.
Range(Chr(i) & "2") will work as long as you don't have more then more than 22 players. I prefer Cells(2, i + 4).Value.
Dim newPlayer As New Player
numPlayers = 10
For i = 1 To numPlayers
Set newPlayer = New Player
newPlayer.Wealth = CLng(40000)
newPlayer.Number = i
Cells(2, i + 4).Value = "Player " & CStr(newPlayer.Number)
Cells(2, i + 5).Value = newPlayer.Wealth
Next