Access Public Function Form and Control Parameters - vba

Question

I set up a public function. It is meant to lock and gray a date control, unless its corresponding combo box control is set to a (bound) value of 2. I made this a public function, so I can call it on load of the form, on current, which fires when the form is navigated back or forth, and when the combo changes. I also have to do this for 2 sets of paired combos and date controls, so having it in a function makes it easier to call for any form/control pairing, when I need to.
This is the public function:
Public Function DateFieldStatus(frm As Form, fkctl As Control, dtctrl As Control)
'Combo Status Values
'ID Combo
'1 = not ok
'2 = ok
'3 = not ok
Select Case frm.fkctl
Case 2
frm.dtctrl.Locked = False
frm.dtctrl.ForeColor = RGB(255, 255, 255)
Case Else
frm.dtctrl.Locked = True
frm.dtctrl.ForeColor = RGB(214, 214, 214)
End Select
frm.dtctrl.Requery
End Function
I have it set to call on load of the main form like this:
Private Sub Form_Load()
If DCount("ID", "tblMainTable") = 0 Then
DoCmd.GoToRecord , , acNewRec
Else
DoCmd.GoToRecord , , acFirst
End If
Me.FirstControl.SetFocus
DateFieldStatus Me.Form, Me.FKDropDown1, Me.dtDateControl1
End Sub
When Launch the main form, I get the following error:
Run-time error '2465':
Application-defined or object-defined error
When I debug, it hightlights this line of the public function:
Select Case frm.fkctl
I'm assuming it doesn't like me combining a form parameter with a control parameter.
Is that not something you can do?
Is there a better way to do this?
Thanks for any help!

Answer 1

frm.fkctl is looking for a control named "fkctl" on the form, and not finding it obviously.
You don't need to pass frm to the function at all - the control object fkctl is sufficient to address the control.
Simply do:
Select Case fkctl.Value
and it will work.
You could do
frm(fkctl.Name)
but it would be kinda silly.

Answer 2

Thanks, I realized I didn't need to declare the form. I declare the control, and when I call the function, the form is . Here is the final solution:
Public Function -
Public Function SmokerStatus(fkctl As Control, dtctrl As Control)
Dim Msg, Style, Title, Response
'ID Combo
'1 = not ok
'2 = ok
'3 = not ok
Msg = "You have changed the option status" & vbCrLf & _
"to a status that doesn't require an option date." & vbCrLf & _
"The corresponding option date has a value. " & vbCrLf & _
"If you would like to delete that date, click yes, otherwise click no, and we will undo."
Style = vbYesNo
Title = "Option Date Only Applies to PAST Option Status"
Select Case fkctl
Case 2
dtctrl.Locked = False
dtctrl.BackColor = RGB(255, 255, 255)
Case Else
If Nz(dtctrl, "") = "" Then
dtctrl.Locked = True
dtctrl.BackColor = RGB(214, 214, 214)
Else
Response = MsgBox(Msg, Style, Title)
If Response = vbYes Then
dtctrl.Value = ""
dtctrl.Locked = True
dtctrl.BackColor = RGB(214, 214, 214)
Else
fkctl.Undo
End If
End If
End Select
dtctrl.Requery
End Function
Here is an example of calling it -
OptionStatus Me.FKOptionCombo, Me.dtOptionDate
Hope this helps others.