Replacing reference with endnote text in Word - vba

Question

I have a text in Word that includes references (1,2,3,...) to endnotes. There are multiple references to the same endnote (for example there are several 1s) created by cross-referencing.
I would like to replace all references with endnote text.
On the internet I have found a code that does that. The problem is that if there are several references to the same endnote, only reference whose position is the first in the document gets to be replaced with text (for example only the first 1, other 1s don't).
I need help how to replace all references with the appropriate endnote text.
Sub endnotes2()
Dim Note As Endnote
Dim NoteReference As String
Dim NoteText As String
For Each Note In ActiveDocument.Endnotes
With Note
NoteText = .Range.Text
NoteReference = .Index
Call Selection.SetRange(.Reference.End, .Reference.End)
Selection.Font.Superscript = True
Selection.TypeText (NoteText)
Selection.Font.Superscript = False
End With
Next Note
Do While ActiveDocument.Endnotes.Count > 0
Call ActiveDocument.Endnotes(1).Delete
Loop
Selection.Find.ClearFormatting
Selection.Find.Font.Superscript = True
Selection.Find.Replacement.ClearFormatting
Selection.Find.Replacement.Font.Superscript = False
With Selection.Find
.Text = ""
.Replacement.Text = " (^&)" 'The ^& here refers to the "found text", so if we found "abc" we will replace it with "(abc)"
.Forward = True
.Wrap = wdFindContinue
.Format = True
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

Answer 1

The following works for me in my simple test.
Since the cross-reference to an endnote does not use superscript by default searching superscript is not a reliable criterium. Also, other things could be superscripted. Cross-references are managed by Word using Ref fields, and these refer to a bookmark placed at the endnote reference when the Insert cross-reference commmand is used.
Such bookmarks begin with _Ref followed by a longish number. And the fields for endnotes use the name NoteRef. So it makes sense to get the bookmark name(s) for the endnote references (there could be more than one), check that they're named using the _Ref pattern then search the document for use of the bookmark(s).
In order to "Find" a field code the pattern ^d is used. So the search term is that, followed by the name of the field code (NoteRef) and the bookmark name. If the search is successful, the field code is deleted and the endnote text is written at this position. The search then continues from this point to the end of the document.
So the code loops through all the endnotes, gets each one's Reference, gets all of its bookmarks, loops the bookmarks, checking the name (as described above) and searches for the NoteRef fields (as described above).
Finally, the original endnote reference is replaced by the endnote text.
Sub WriteEndNoteToAllEndNoteRefs()
Dim sEndNoteText As String
Dim rngEndNoteRef As Word.Range, rngSearch As Word.Range
Dim doc As Word.Document
Dim en As Word.Endnote
Dim bkm As Word.Bookmark
Dim bFound As Boolean
Set doc = ActiveDocument
For Each en In doc.Endnotes
Set rngEndNoteRef = en.Reference
sEndNoteText = en.Range.Text
For Each bkm In rngEndNoteRef.Bookmarks
If Left(bkm.Name, 4) = "_Ref" Then
Set rngSearch = doc.content
rngSearch.TextRetrievalMode.IncludeFieldCodes = True
Do
With rngSearch.Find
.Text = "^d NoteRef " & bkm.Name
.wrap = wdFindStop
bFound = .Execute
If bFound Then
rngSearch.Fields(1).Delete
rngSearch.Text = sEndNoteText
rngSearch.End = doc.content.End
End If
End With
Loop While bFound
End If
Next
rngEndNoteRef = sEndNoteText
Next
End Sub