Find Numerals in Text and insert vbCr immediately before Numerals - vba

Question

I have a word document with numerical references spread throughout the body of my text. For example "text string 1" ###:### "text string 2". Note the colon in the middle of the numberical reference. The numerical references may range from 1-999 on either side of the colon, but every reference has at least one number on each side of the colon with no more than 3 numbers on either side.
I need a routine that scans the entire document, identifies each numeral reference and then enters a carriage return BEFORE the numerical reference.... so every numerical reference would start a paragraph in the document. To illustrate this, the example above would be transformed to...
"Text string 1"
"###:###" "Text String 2"
I've tried modifying a Find/Replace operation to do this (to the point I'm going cross eyed) but can't seem to figure it out.
Any help would be greatly appreciated. Thank you!

Answer 1

I think using RegExp is a bit complicated here as long as there is Find-Replace feature in MS Word. Try with this code:
Sub Find_Replace_Macro()
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find
.Text = "([ ])([0-9]{1;3}:[0-9]{1;3})" 'solution for non-English version of MS-Word
.Text = "([ ])([0-9]{1,3}:[0-9]{1,3})" 'solution for English version of MS-Word
.Replacement.Text = "^13\2"
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchAllWordForms = False
.MatchSoundsLike = False
.MatchWildcards = True
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

Answer 2

You can do this with a simple Regular Expression Replace Function...
Sub TestSub()
Dim StrText
StrText = "Blajdflajdflaj 123:133 lajdflkaj123:343 alkdjflakjd 444:78 alkjdlfajkdlksjalk"
Debug.Print AddNewLine(StrText)
End Sub
Function AddNewLine(strInput)
Dim objRegEx
Set objRegEx = CreateObject("VBScript.RegExp")
objRegEx.IgnoreCase = True
objRegEx.Global = True
objRegEx.Pattern = "\d{1,3}\:\d{1,3}"
'Remove one of the vbCrLf's if you only want a single New Line
AddNewLine = objRegEx.Replace(strInput, vbCrLf & vbCrLf & "$&")
End Function
The above routine will create the below output:
Blajdflajdflaj
123:133 lajdflkaj
123:343 alkdjflakjd
444:78 alkjdlfajkdlksjalk
If your working with a MS Word Document, you can test with:
StrText = ActiveDocument.Content.Text
For some extra reading on Substitutions in Regular Expressions please see:
http://msdn.microsoft.com/en-us/library/ewy2t5e0.aspx