CMake: How to append extra compile definition to a dependent lib build - cmake

Question

I have a shared library, libShared, which used to build different executables. What do I want to do is based on the build executable to add additional compile definition to the shared library.
CMakeLists.txt in my lib folder:
...
add_definition(-Dfoo -Dbar)
add_library(shared ${SOURCES})
CMakeLists.txt in exe1 folder:
...
add_executable(exe1 ${SOUCE_FILES})
add_dependencies(exe1 shared)
# <How Do I append -DForExe1 compile definition to shared>?
target_link_libraries(exe1 shared)
CMakeLists.txt in exe2 folder:
...
add_executable(exe2 ${SOURCES})
add_dependentcies(exe2 shared)
# <How Do I append -DForExe2 compile definition to shared>?
target_link_libraries(exe2 shared)
How do I do this in CMake?

Answer 1

One cannot have single library target with different compile definitions.
Different compile definitions means different compilation actions, resulted in different objects files. But this would defeat the very concept of a library as something already compiled (and linked, in case of shared libraries).
If you have small number of possible compile definitions' set for a library, you may define library target for every set:
# Common definitions for any library.
add_definition(-Dfoo -Dbar)
# Common sources for any library
set(LIB_SOURCES ...)
# The library specialized for exe1.
add_library(lib_exe1 SHARED ${LIB_SOURCES})
# Library-specific definitions
target_compile_definitions(lib_exe1 PRIVATE -DForExe1)
# The library specialized for exe2.
add_library(lib_exe2 SHARED ${LIB_SOURCES})
# Library-specific definitions
target_compile_definitions(lib_exe2 PRIVATE -DForExe2)
Resulted libraries may be used when needed:
add_executable(exe1 ${SOUCE_FILES})
target_link_libraries(exe1 lib_exe1)
If your library should be parametrized for some compile definition, consider to create a CMake function/macro, which creates a library instance when needed:
function(add_lib_for lib_name purpose_name)
add_library(${lib_name} SHARED <sources>)
target_compile_definitions(${lib_name} PRIVATE
-Dfoo -Dbar # Common definitions
-DFor${purpose_name} # Specific definition
)
endfunction()
Usage:
add_executable(exe1 ${SOUCE_FILES})
add_lib_for(lib_exe1 Exe1)
target_link_libraries(exe1 lib_exe1)