Paste a range variable at the location of another variable - vba

Question

Im setting the location I want to paste at with column_find. I want to paste a range (user_data) at that cell. The macro runs but only pastes 1 value from the range. What am I doing wrong?
Sub Column_Locate()
Dim current_month As Variant
Dim column_find As Range
Dim user_data As Range
current_month = Worksheets("Inputs").Cells(4, 4).Value
Set column_find = Worksheets("Feeder").Range("E2:CZ2").Find(current_month, LookIn:=xlValues, LookAt:=xlWhole).Offset(8, -1)
Debug.Print column_find.Address(0, 0)
Set user_data = Worksheets("Unique Users Data").Range("B2:C3")
Worksheets("Feeder").Select
column_find = user_data
End Sub

Answer 1

you have to adjust the size of "target" range (i.e. column_find) accordingly to the "source" one (i.e. user_data)
also avoid use of Select/Selection/Activate/ActiveXXX pattern , which is both time consuming and prone to have you quickly lose control over your ranges reference and adopt a fully qualified range reference pattern (for instance with the use of With... End With construct)
so you would code (explanations in comments):
Option Explicit
Sub Column_Locate()
Dim current_month As Variant
Dim column_find As Range
Dim user_data As Range
current_month = Worksheets("Inputs").Cells(4, 4).Value
Set user_data = Worksheets("Unique Users Data").Range("B2:C3")
With Worksheets("Feeder") 'reference "Feeder" worksheet
Set column_find = .Range("E2:CZ2").Find(current_month, LookIn:=xlValues, LookAt:=xlWhole).Offset(8, -1) 'search referenced sheet range "E2:CZ2" for 'current_month' value
If Not column_find Is Nothing Then 'if the searched value has been found
With user_data 'reference "source" range
Debug.Print column_find.Address(0, 0)
column_find.Resize(.Rows.Count, .Columns.Count).Value = user_data.Value ' reference a "target" range as the one with found value but with same size as "source" range and write values
End With
End If
End With
End Sub