Extracting values to fit into changing equations - vba

Question

Not sure how to approach this situation. The best way to explain it might be visually, below is the diluted situation of what I have at hand:
Sheet 1:
Column A Column B
Chocolate 20
Vanilla 10
Strawberry 30
Sheet 2:
Column A
Chocolate + Vanilla
Vanilla / Strawberry
Chocolate / (Strawberry + Vanilla)
Goal:
Sheet 2:
Column A Column B
Chocolate + Vanilla 30
Vanilla / Strawberry 1/3
Chocolate / (Strawberry + Vanilla) 1/2
The trouble I'm having is, I could do an index/match or vlookup approach and pull the numbers corresponding to the flavors (chocolate, vanilla, strawberry) individually - but is there a way for Excel to know what arithmetic function based off Sheet 2, column A to follow instead of me manually adjusting each row to fit the right formula?
So essentially, some sort of function or VBA method that will tell Excel, "Grab & understand the arithmetic symbol/equation in that row and follow that command" so I don't have to adjust each row to the correct math symbol?

Answer 1

if your formulas keep sticking to Excel UI formula input rules then you could give this a try
Sub Main()
Dim cell As Range
Dim strng As String
Dim element As Variant
Dim elementValue As Variant
With Worksheets("Sheet2")
For Each cell In .Range("A1", .Cells(.Rows.Count, 1).End(xlUp))
strng = cell.Value2
For Each element In Split(Replace(Replace(cell.Value2, "(", ""), ")", ""))
If GetValue(CStr(element), elementValue) Then strng = Replace(strng, element, elementValue)
Next
cell.Offset(, 1).Formula = Replace("=" & strng, " ", "")
Next
End With
End Sub
Function GetValue(elementName As String, elementValue As Variant) As Boolean
Dim f As Range
With Worksheets("Sheet1")
Set f = .Range("A1", .Cells(.Rows.Count, 1).End(xlUp)).Find(what:=elementName, lookat:=xlWhole, LookIn:=xlValues)
If Not f Is Nothing Then
elementValue = f.Offset(, 1)
GetValue = True
End If
End With
End Function

Answer 2

Basically we could use RegEx to recognize the 'name' and then get the address of the value of the 'name'. Then we could derive a formula in Sheet2.
Sub Test()
Set mysheet2 = ThisWorkbook.Worksheets("Sheet2")
Set regEx = New RegExp
regEx.Pattern = "\w+"
regEx.Global = True
For i = 1 To mysheet2.UsedRange.Rows.Count
formula_str = mysheet2.Cells(i, 1).Value
Set oMatches = regEx.Execute(formula_str)
For Each oMatch In oMatches
formula_str = Replace(formula_str, oMatch, getAdd(oMatch))
Next
mysheet2.Cells(i, 2) = "=" & formula_str
Next
End Sub
'Function to get the address of 'names'
Function getAdd(keyword)
Set mysheet1 = ThisWorkbook.Worksheets("Sheet1")
getAdd = ""
With mysheet1
For i = 1 To .UsedRange.Rows.Count
If .Cells(i, 1) = keyword Then
getAdd = mysheet1.Name & "!" & .Cells(i, 2).Address
Exit For
End If
Next
End With
End Function
Currently this solution has the limit that all the 'names' must be alphabet format. If you want to use names containing digits and other characters, you should change the RegEx pattern.