Can't get a VLookup to reference another workbook - vba

Question

So I'm relatively new to VBA and I'm trying to get a Vlookup to return a value searching on another workbook. The thing is, i keep getting the classic
1004 error
on the line of the Vlookup. I'm just trying to search for a number on the current workbook and find it on another one, returning the date associated to it, but it doesn't give me anything
I've seen many people asking stuff like this, but haven't seen the answer to my specififc problema, which I guess is common among beginners. So, any help on how to make a better code, besides the actual solution to my problema is appreciated.
Sub Add_Dates()
Application.CutCopyMode = False
Dim Lastzip As Integer, Val As Integer
'Open this workbook just in case it's not yet selected
Workbooks.Open ("C:\(%)\combine zslb and zpdi.xlsm")
LastRow = Range("A1").End(x1Down).Row
'get the value for the last row
Workbooks.Open ("C:\(%)\zipe zpdi zslb.xlsx")
Sheets("ZSLB").Activate
ActiveCell.SpecialCells(x1LastCell).Select
Lastzip = ActiveCell.Row
'Same, get the value of the last row of this wbk,
'which changes everyday, so can't be a fix value
Workbooks("combine zslb and zpdi.xlsm").Sheets("zslb").Activate
Range("A2").End(x1ToRight).Select
col = Selection.Offset(0,1).Column
For i = 2 to LastRow
Val = Application.VLookup(Cells(i, 1), Workbooks("zipe zpdi zslb.xlsx"). _
Sheets("ZSLB").Range(Cells(2, 1), Cells(Lastzip, 31)), 31, False)
Cells(i, col).Value = Val
Next i
End Sub

Answer 1

Untested but compiled:
Sub Add_Dates()
Const WB_PATH As String = "C:\(%)\"
Application.CutCopyMode = False
Dim LastZipRow As Long, LastCombRow As Long, col As Long, v
Dim wbComb As Workbook, wbZipe As Workbook, i As Long
Dim shtComb As Workbook, shtZipe As Workbook, rngLookup As Range
Set wbComb = GetWorkbook(WB_PATH, "combine zslb and zpdi.xlsm")
Set wbZipe = GetWorkbook(WB_PATH, "zipe zpdi zslb.xlsx")
Set shtComb = wbComb.Sheets("ZSLB")
Set shtZipe = wbZipe.Sheets("ZSLB")
LastCombRow = shtComb.Range("A1").End(xlDown).Row
LastZipRow = shtZipe.SpecialCells(xlLastCell).Row
col = shtComb.Range("A2").End(xlToRight).Column
Set rngLookup = shtZipe.Range(shtZipe.Cells(2, 1), _
shtZipe.Cells(LastZipRow, 31))
For i = 2 To LastCombRow
v = Application.VLookup(shtComb.Cells(i, 1), rngLookup, 31, False)
shtComb.Cells(i, col).Value = IIf(IsError(v), "???", v)
Next i
End Sub
'return a reference to an already-open file, or if not open then open it
Function GetWorkbook(wbPath, wbName) As Workbook
Dim rv As Workbook
If Right(wbPath, 1) <> "\" Then wbPath = wbPath & "\"
On Error Resume Next '<< ignore error if file not open
Set rv = Workbooks(wbName)
On Error GoTo 0
'note there's no error handling here to account for "file not found"
If rv Is Nothing Then Set rv = Workbooks.Open(wbPath & wbName)
Set GetWorkbook = rv
End Function
Note - in your constants you're using a "1" and not "l" - e.g. x1Down.