VB.NET Filling form with graphics conundrum - vb.net

Question

Afternoon, I have a maths-formula type query in VB.NET
I have a screen, it can be resized and the only input I get from the user, is the quantity of "balls" that go inside the screen.
I know I need to square root the width and height, to get my "quantity" of balls for a best-as equal rows and columns - but Im a bit stuffed on calculating:
The size of the balls.
The distance between the balls (if need-be, the balls need to be smaller)
and as per not-my example below, I need the ball start position to be at the top left corner of the form.
So, open up a copy of VS, add a new winforms project, paste the code below into the Paint event of the form and run it.
So what I need is: A indeterminate amount of balls to generate (fed by a user) to fill up the form, as equally best on the X and Y axis to fill up the form staying the same size and if possible, a little distance between them, say, a quarter of the size of the ball itself.
Feel free to resize the screen or change the _BallsInTotal variable for it to auto-generate the amount of balls.
Dim _BallsInTotal As Integer
_BallsInTotal = 100
Dim TotalColumns As Integer
Dim TotalRows As Integer
TotalColumns = Math.Sqrt(_BallsInTotal)
TotalRows = Math.Sqrt(_BallsInTotal)
Dim BallWidth As Single = 20
Dim BallHeight As Single = 20
Dim BallPositionX As Long = BallWidth * 2
Dim BallPositionY As Long = BallHeight * 2
Dim solidBrush As New SolidBrush(Color.FromArgb(255, 255, 0, 0))
Dim rows As Single
Dim columns As Single
For columns = 1 To TotalColumns
For rows = 1 To TotalRows
e.Graphics.FillEllipse(solidBrush, BallPositionX * columns, BallPositionY * rows, BallWidth , BallHeight )
Next
Next
Ive been scratching my head for the last two hour where Im at the point where its going to bleed! (seriously, its doing my head in).

Answer 1

What I've added is an InputBox that allows the user to specify the total number of balls. I placed the code in the OnPaint event for drawing the graphics. I've calculated the width of the columns and rows based on the form width/height. I'm using variables for the column/row in the For loops to track which column and row I'm drawing in, then using the column/row width/height to find my x and y (plus an additional .1 of the column/row width/height for spacing). And finally using .8 of the column/row width/height for how much space I want the ball to take up in the column/row.
Public Class Form1
Dim _total As Int32 = 120
Private Sub Form1_Paint(sender As Object, e As PaintEventArgs) Handles Me.Paint
Dim columns As Int32 = Math.Ceiling(Math.Sqrt(_total))
Dim rows As Int32 = Math.Ceiling(Math.Sqrt(_total))
Dim width As Int32 = Me.ClientSize.Width
Dim height As Int32 = Me.ClientSize.Height
Dim columnWidth As Int32 = width / columns
Dim rowHeight As Int32 = height / rows
Dim brush As Brush = New SolidBrush(Color.FromArgb(255, 255, 0, 0))
Me.SuspendLayout()
Dim painted As Int32 = 0
For r As Int32 = 0 To rows - 1
For c As Int32 = 0 To columns - 1
Dim x As Int32 = (c * columnWidth) + (columnWidth * 0.1)
Dim y As Int32 = (r * rowHeight) + (rowHeight * 0.1)
e.Graphics.FillEllipse(brush, New Rectangle(x, y, columnWidth * 0.8, rowHeight * 0.8))
painted += 1
If painted = _total Then
Me.ResumeLayout()
Exit Sub
End If
Next
Next
End Sub
Private Sub Form1_SizeChanged(sender As Object, e As EventArgs) Handles Me.SizeChanged
Me.Invalidate()
End Sub
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim input As String = InputBox("Enter a total.")
Dim number As Int32 = 0
If Int32.TryParse(input, number) Then
_total = number
Me.Invalidate()
End If
End Sub
End Class