Finding string in a specific format - vba

Question

I have the below code to "automatically" download Outlook emails to a specific local directory.
I would like to be more specific in regards to the file name for the saved mail.
I need to search the email subject and or body to find a string of text in the format AANNNNNNA, where A is a letter and N is a number. If found use that in place of the subject body in the resultant file name, if none is present use the subject of the email.
I can't figure out how to search for the format above.
Option Explicit
Public Sub SaveMessageAsMsg()
Dim oMail As Outlook.MailItem
Dim objItem As Object
Dim sPath As String
Dim dtDate As Date
Dim sName As String
For Each objItem In ActiveExplorer.Selection
If objItem.MessageClass = "IPM.Note" Then
Set oMail = objItem
sName = oMail.Subject
ReplaceCharsForFileName sName, "-"
dtDate = oMail.ReceivedTime
sName = Format(dtDate, "yyyymmdd", vbUseSystemDayOfWeek, _
vbUseSystem) & Format(dtDate, "-hhnnss", _
vbUseSystemDayOfWeek, vbUseSystem) & "-" & sName & ".msg"
sPath = "C:\Users\XXXXXX\Desktop\Test\"
Debug.Print sPath & sName
oMail.SaveAs sPath & sName, olMSG
End If
Next
End Sub
Private Sub ReplaceCharsForFileName(sName As String, sChr As String)
sName = Replace(sName, "'", sChr)
sName = Replace(sName, "*", sChr)
sName = Replace(sName, "/", sChr)
sName = Replace(sName, "\", sChr)
sName = Replace(sName, ":", sChr)
sName = Replace(sName, "?", sChr)
sName = Replace(sName, Chr(34), sChr)
sName = Replace(sName, "<", sChr)
sName = Replace(sName, ">", sChr)
sName = Replace(sName, "|", sChr)
End Sub

Answer 1

Here's one way of doing it by simply parsing the string:
Public Function FindCode(sCode As String) As String
Dim sCheck As String
Dim nIndex As Integer
For nIndex = 1 To Len(sCode) - 8
sCheck = Mid$(sCode, nIndex, 9)
If IsNumeric(Mid$(sCheck, 3, 6)) And _
Not IsNumeric(Mid$(sCheck, 1, 2)) And _
Not IsNumeric(Mid$(sCheck, 9, 1)) Then
FindCode = sCheck
Exit Function
End If
Next
FindCode = "[not found]"
End Function

Answer 2

Regex might be an option for you (https://learn.microsoft.com/en-us/dotnet/standard/base-types/regular-expression-language-quick-reference) but given the simplicity of the search pattern then the Like operator seems an obvious choice (https://msdn.microsoft.com/VBA/Language-Reference-VBA/articles/like-operator).
The only drawback with Like is that it doesn't return the location of the match in your search string (it just returns True or False), so you'd need to iterate your search string in batches of 9 characters to find the match and then return it.
Public Sub RunMe()
Dim str As String
Dim nme As String
str = "To whom it may concern, find this: AB123456C. Happy coding, Ambie"
nme = FindName(str)
If nme <> "" Then MsgBox nme
End Sub
Private Function FindName(searchText As String) As String
Const PTRN As String = "[A-Za-z][A-Za-z]######[A-Za-z]"
Dim txt As String
Dim i As Long
If Len(searchText) >= 9 Then
For i = 1 To Len(searchText) - 9 + 1
txt = Mid(searchText, i, 9)
If txt Like PTRN Then
FindName = txt
Exit Function
End If
Next
End If
End Function