Using a macro to sort data from instrumentation software - vba

Question

So I use an instrumentation software at work that outputs readings to a csv excel file. Because of the length of the test and the readings every 30 seconds, I accumulate a few thousand rows for every 24 hours of the test. When the test runs, it reads things that I don't need readings of so I have to go through the sheet manually and replace the "false" readings with zeros.
What I would like to do is use a command button to prompt the user to select a column to sort and apply a range of values so if it falls within that range, it returns the value to the cell and if it doesn't fall within the range, it returns a 0. I have done this with smaller sheets with extra columns (see attached file) but I'm not super familiar with Macros or VBA so I'm not sure where to get started.
Can anyone give me a hand?

Answer 1

This can be done as follows.
1) Go to Developer tab in the Excel ribbon. Click Insert, choose a Command Button (ActiveX Control) and place it onto the sheet where you want to have it.
2) Double-click the button, this will open up the editor. You should see:
Private Sub CommandButton1_Click()
End Sub
3) Add the line UserForm1.Show inside of this block of code. This should now look like:
Private Sub CommandButton1_Click()
UserForm1.Show
End Sub
4) Now we will create the userform. On the left side of the editor you will see a section called "Projects - VBA Project", in this list you should see your Workbook. Right click the name of your workbook and click Insert -> UserForm.
5) Use the toolbox to drag the correct components into the Userform. You are free to customize this form as you see fit to add or remove functionality based on your needs. I made mine look like this:
6) In the projects tab you will see your userform named UserForm1. Right click this userform and click "View Code". Paste the following code:
Private Sub CommandButton1_Click()
Unload UserForm1
End Sub
Private Sub UserForm_Initialize()
Dim lastColumn As Long
lastColumn = Worksheets("Sheet1").Cells(1,Columns.Count).End(xlToLeft).Column
For i = 1 To lastColumn
UserForm1.ComboBox1.AddItem (Worksheets("Sheet1").Cells(1, i))
Next
End Sub
Private Sub CommandButton2_Click()
Dim columnName As String
Dim columnIndex As Integer
Dim min As Double
Dim max As Double
If Not (ComboBox1.SelText = "" And TextBox1.Text = "" And TextBox2.Text = "") Then
columnName = ComboBox1.SelText
min = TextBox1.Text
max = TextBox2.Text
Dim lastColumn As Long
lastColumn = Worksheets("Sheet1").Cells(1, Columns.Count).End(xlToLeft).Column
For i = 1 To lastColumn
If Worksheets("Sheet1").Cells(1, i).Value = columnName Then
columnIndex = i
End If
Next
Dim cellValue As Double
Dim lastRow As Long
lastRow = Worksheets("Sheet1").Cells(Rows.Count, 1).End(xlUp).Row
For i = 2 To lastRow
cellValue = Worksheets("Sheet1").Cells(i, columnIndex).Value
' MsgBox CStr(cellValue) + "--" + CStr(cellValue > min) + "--" + CStr(cellValue < max)
If Not (cellValue >= min And cellValue <= max) Then
Worksheets("Sheet1").Cells(i, columnIndex).Value = 0
End If
Next
End If
Unload UserForm1
End Sub
7) Change the component names such as CommandButton, ComboBox1, etc. to match your UserForm.
What does the code do?
Initializing: As soon as the UserForm is called it passes through the method UserForm_Initialize(). This method looks through your WorkSheet and determines the name of all the columns. It then adds these to the ComboBox.
Command Button 1: "Cancel", exits the UserForm without doing anything.
Command Button 2: "Confirm", this method goes to your selected column, checks within the desired range. If a value falls outside that range then it will set it to 0.
I hope this help!!