VBA: Add data to a graph [closed] - vba

Question

Closed. This question needs to be more focused. It is not currently accepting answers.
Want to improve this question? Update the question so it focuses on one problem only by editing this post.
Closed 5 years ago.
Improve this question
I am new to VBA but I got this project to work on. I have this excel macro file that takes in as user input a specific date (month, day, year) and displays the graph of that day using the data read from the file of that selected date. Each file is named like "xxxx_20170706.csv". I need to modify this file to achieve below.
Each file is generated once a day containing the temperatures recorded every minute. The problem is, because each file is generated only once a day, and it contains the temperature data of the previous day (data keep being recorded from 00:00 till 23:59), you cannot check or use data of today. Basically, you have to wait until the next day if you wanna see the graph of a day.
In order to fix this issue, we decided to generate one file every hour for each day (that is, 24 files generated per day), and each file contains data of the previous hour. For example, at 1:00am of a day, a file is generated containing temperature data of time from 0:00am till 0:59am of the day. This way, we will be able to see the data of even today.
This means, at 5:30 in the morning, there should be 5 different files generated.
The problem I am having is, I am not sure how I can generate a graph from multiple files. The user input will stay the same, and only prompt a specific date they want to see the temperature data of. The output needs to be one graph reflecting temperature data of the date that exist at that point.
Each file will become named "xxxx_20170706_YY.csv" where YY is the 2 digit hours (from 00 up to 23).
I tried using loop incrementing i and adding it to the end of the file name so it can keep reading the existing files of the selected date. However, it did not work and only displayed the graph of data from the last file read.
If there are 5 files for a day, then all of these 5 files must be used for the graph.
How could this be achieved? An idea I came up with is, I create a new excel file, and each time a file is read in a for-loop, I keep adding the data at the bottom of the file, and at the end read that new excel file once, and generate the graph.
Is there any other better way? Thanks in advance for your help!

Answer 1

I would do that this way:
loop through the hours to current hour to get the file names
inside a loop create query (string)
create connection
create recordset
dump data into Excel sheet, which is used as a source for chart
Please, read my comments in below code:
Option Explicit
'needs reference to MS ActiveX Data Objects x.x Library
Sub GetCsvData()
Dim sPath As String, sFileName As String
Dim i As Integer, iCurrHour As Integer
Dim sSQL As String, sConn As String
Dim oConn As ADODB.Connection, oRst As Recordset, oWsh As Worksheet
On Error GoTo Err_GetCsvData
iCurrHour = Hour(Now) - 1
For i = 0 To iCurrHour
sFileName = "xxxx_" & Format(Date, "yyyyMMdd") & "_" & Right("00" & CStr(i), 2) & ".csv"
sSQL = sSQL & "SELECT * FROM " & sFileName & vbCr & "UNION ALL" & vbCr
Next
sSQL = "SELECT fnl.*" & vbCr & "FROM (" & vbCr & sSQL & ") AS fnl;"
MsgBox sSQL
'temporary exit sub; remove below line
GoTo Exit_GetCsvData
sPath = "c:\txtFilesFolder\" 'path have to ends with "\"
'change HDR=Yes if the first row of csv file contains the names of columns
sConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & sPath & ";Extended Properties='text;HDR=No;FMT=Delimited';"
Set oConn = New ADODB.Connection
With oConn
.ConnectionString = sConn
.Open
End With
Set oRst = New ADODB.Recordset
oRst.Open sSQL, oConn, adOpenStatic, adLockReadOnly
Set oWsh = ThisWorkbook.Worksheets("SourceSheetForChart")
oWsh.Range("A1").CopyFromRecordset oRst
Exit_GetCsvData:
Set oWsh = Nothing
If Not oRst Is Nothing Then oRst.Close
Set oRst = Nothing
If Not oConn Is Nothing Then oConn.Close
Set oConn = Nothing
Exit Sub
Err_GetCsvData:
MsgBox Err.Description, vbExclamation, Err.Number
Resume Exit_GetCsvData
End Sub
Note: if your text files contain very specific delimiter or decimal separator, you have create schema.ini file.
For further details, please see:
Much ADO about text files
Schema.ini File
Good luck!