how to "sync" VB Project after dynamically adding a function? - vba

Question

I am writing an Excel VBA project that creates new functions during code execution.
The newly added functions need to be able to be executed immediately.
While I do see the new functions added, I receive an "1004" run-time error on the first execution.
The below code adds a new function testMethod into an existing DynamicFunctions module (if the function is not already there) and executes it.
code snippets taken from Dynamic Code Generate & Execute#VBA and from Programming The VBA Editor
The error message:
"Run-time error '1004':
Cannot run the macro 'testMethod'. The macro may not be available in this workbook or all macros may be disabled"
(notice on second execution, the function already in the module so the code simply executes it and pops the message box)
Dim code As String
code = "Public Function testMethod()" & vbNewLine & _
vbTab & "MsgBox """ & Time & """" & vbNewLine & _
"End Function"
Dim methodExist As Boolean
methodExist = checkProcName("testMethod")
If (methodExist = False) Then
Dim VBComp As VBIDE.VBComponent
Set VBComp = ThisWorkbook.VBProject.VBComponents("DynamicFunctions")
Call VBComp.CodeModule.AddFromString(code)
End If
Application.Run "testMethod"
Function checkProcName(sProcName As String) As Boolean
' ===========================================================================
' Found on http://www.cpearson.com at http://www.cpearson.com/excel/vbe.aspx
' then modified
'
' USAGE:
' to check if a procedure exists, call 'checkProcName' passing
' in the target workbook (which should be open), the Module,
' and the procedure name
'
' ===========================================================================
Dim oVBProj As VBIDE.VBProject
Dim VBComp As VBIDE.VBComponent
Dim CodeMod As VBIDE.CodeModule
Dim ProcName As String
Dim ProcKind As VBIDE.vbext_ProcKind
checkProcName = False
Set VBProj = ThisWorkbook.VBProject
Set VBComp = VBProj.VBComponents("DynamicFunctions")
Set CodeMod = VBComp.CodeModule
With CodeMod
LineNum = .CountOfDeclarationLines + 1
Do Until LineNum >= .CountOfLines
ProcName = .ProcOfLine(LineNum, ProcKind)
If ProcName = sProcName Then
checkProcName = True
Exit Do
End If
Debug.Print ProcName
LineNum = .ProcStartLine(ProcName, ProcKind) + .ProcCountLines(ProcName, ProcKind) + 1
Loop
End With
End Function

Answer 1

Unless there is a specific reason you need to have the DynamicFunctions module in your project, you could always create one on the fly, run the code and delete when done.
Public Sub CreateModuleRunMethodAndDelete()
Dim code As String
code = "Public Function testMethod()" & vbNewLine & _
vbTab & "MsgBox """ & Time & """" & vbNewLine & _
"End Function"
'Create and append code
With ThisWorkbook.VBProject
With .VBComponents.Add(vbext_ct_StdModule)
.Name = "Temp"
.CodeModule.AddFromString code
End With
End With
'Run
Application.Run "testMethod"
'Delete module
With ThisWorkbook.VBProject
.VBComponents.Remove .VBComponents("Temp")
End With
End Sub
Edit:
Create procedure if not exists and run.
Public Sub RunMethod()
Dim code As String
code = "Public Function testMethod()" & vbNewLine & _
vbTab & "MsgBox """ & Time & """" & vbNewLine & _
"End Function"
If Not checkProcName("testMethod") Then
ThisWorkbook.VBProject.VBComponents("DynamicFunctions").CodeModule.AddFromString code
End If
Application.Run "testMethod"
End Sub