Error while creating PivotTable - vba

Question

I am writing a code to create an Pivot table. I recorded the macros, and then simplified it to easy understanding.
While executing the code, I get error
subscript out of range.
I checked with the worksheet name, it is the same name I have defined.
I'm clueless, why it is not working. Below, is the code I tried.
Sub table()
Dim pvtcache As PivotCache
Dim pvttbl As pivottable
Dim pvtsht As Worksheet
Set pvtcache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _
"Preparation Sheet!R1C1:R1048576C9")
Set pvtsht = Worksheets("LP")
On Error Resume Next
Set pvttbl = pvtsht.PivotTables("PivotTable3")
On Error GoTo 0
If pvttbl Is Nothing Then
Set pvttbl = pvtsht.PivotTables.Add(PivotCache:=pvtcache, TableDestination:=pvtsht.Range("A3"), TableName:="PivotTable3")
With pvttbl
With .PivotFields("DL")
.Orientation = xlRowField
.Position = 1
End With
With .PivotFields("Colour")
.Orientation = xlColumnField
.Position = 1
End With
End With
Else
' just refresh the Pivot cache with the updated Range
pvttbl.ChangePivotCache pvtcache
End If
End Sub
below is the code, from macros
Sub Macro8()
Sheets.Add
ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:= _
"Preparation Sheet!R1C1:R1048576C9", Version:=xlPivotTableVersion15). _
CreatePivotTable TableDestination:="Sheet4!R3C1", TableName:="PivotTable2" _
, DefaultVersion:=xlPivotTableVersion15
Sheets("Sheet4").Select
Cells(3, 1).Select
With ActiveSheet.PivotTables("PivotTable2").PivotFields("DL")
.Orientation = xlRowField
.Position = 1
End With
ActiveSheet.PivotTables("PivotTable2").AddDataField ActiveSheet.PivotTables( _
"PivotTable2").PivotFields("Colour"), "Count of Colour", xlCount
With ActiveSheet.PivotTables("PivotTable2").PivotFields("Colour")
.Orientation = xlColumnField
.Position = 1
End With
End Sub

Answer 1

If your worksheet names contain spaces "Preparation Sheet!R1C1:R1048576C9" you need to enclose the worksheet name in ''
"'Preparation Sheet'!R1C1:R1048576C9"
or avoid spaces in it.
Edit
Add this function to your module
Public Function PivotTableExistsInWorksheet(pvWorksheet As Worksheet, pvTableName As String) As Boolean
Dim pvTable As PivotTable
PivotTableExistsInWorksheet = False 'Default
For Each pvTable In pvWorksheet.PivotTables
If pvTable.Name = pvTableName Then
PivotTableExistsInWorksheet = True
Exit Function
End If
Next pvTable
End Function
and use
If PivotTableExistsInWorksheet(pvtsht, "PivotTable3") Then
Set pvttbl = pvtsht.PivotTables("PivotTable3")
End If
instead of the On Error Resume Next … Goto 0 block to see if this works.