Access Context Menu - vb.net

Question

I'm trying to access the Context Menu UI AutomationElement of Notepad, however I am struggling to do so:
Imports System.Windows.Automation
Imports System.Windows.Forms
Module AutomateNotepad
Sub Main()
Dim wNotepad, document As AutomationElement
wNotepad = AutomationElement.RootElement.FindFirst(TreeScope.Children, New PropertyCondition(AutomationElement.NameProperty, "Untitled - Notepad"))
document = wNotepad.FindFirst(TreeScope.Children, New PropertyCondition(AutomationElement.LocalizedControlTypeProperty, "document"))
document.SetFocus()
SendKeys.SendWait("+{F10}")
context = AutomationElement.RootElement.FindFirst(TreeScope.Children, New PropertyCondition(AutomationElement.NameProperty, "context"))
While context Is Nothing
Console.WriteLine("Trying to get context again")
Threading.Thread.Sleep(100)
context = AutomationElement.RootElement.FindFirst(TreeScope.Children, New PropertyCondition(AutomationElement.NameProperty, "context"))
End While
MsgBox("Found it!")
End Sub
End Module
My problem is that when I run the application, the notepad context menu opens but UIAutomation never appears to get the AutomationElement of it...
This is a screenshot from Inspect.exe:
Given the inspect picture and the structure it presents, I see no reason why this would be occurring... Does anyone know where I might be going wrong?
P.S. I'm very new to VB.NET but have been working with VBA for 2-3 years so I apologise for any bad habits I may have...

Answer 1

I've found a solution to my issue. The trick is to subscribe to UIAutomation OpenMenuEvent. To do this I created a ContextWatcher class:
Public Class ContextWatcher
Public Shared Menu As AutomationElement
Private Shared _EventHandler As AutomationEventHandler
Public Shared Sub trackContext()
_EventHandler = New AutomationEventHandler(AddressOf OnContextOpened)
Automation.AddAutomationEventHandler(AutomationElement.MenuOpenedEvent, AutomationElement.RootElement, TreeScope.Descendants, _EventHandler)
End Sub
Public Shared Sub untrackContext()
Automation.RemoveAutomationEventHandler(AutomationElement.MenuOpenedEvent, AutomationElement.RootElement, _EventHandler)
End Sub
Private Shared Sub OnContextOpened(src As Object, args As AutomationEventArgs)
Console.WriteLine("Menu opened.")
Dim element = TryCast(src, AutomationElement)
If element Is Nothing Then
Return
Else
Menu = element
End If
End Sub
End Class
To access the context menu I can use this:
ContextWatcher.trackContext()
SendKeys.SendWait("+{F10}")
Dim context As AutomationElement
context = ContextWatcher.Menu
While context Is Nothing
Console.WriteLine("Trying to get context again")
Threading.Thread.Sleep(100)
context = ContextWatcher.Menu
End While
' Do Stuff with context menu
ContextWatcher.untrackContext()
Imports System.Windows.Automation
Imports System.Windows.Forms
Module AutomateNotepad
Sub Main()
Dim wNotepad, document As AutomationElement
'Get 'Untitled - Notepad' main window
wNotepad = AutomationElement.RootElement.FindFirst(TreeScope.Children, New PropertyCondition(AutomationElement.NameProperty, "Untitled - Notepad"))
'Get Notepad document element
document = wNotepad.FindFirst(TreeScope.Children, New PropertyCondition(AutomationElement.LocalizedControlTypeProperty, "document"))
'Set focus to document
document.SetFocus()
'Start watching for context menu
ContextWatcher.trackContext()
'Open context menu
SendKeys.SendWait("+{F10}")
'Get context menu from ContextWatcher class
Dim context As AutomationElement
context = ContextWatcher.Menu
While context Is Nothing
Console.WriteLine("Trying to get context again")
Threading.Thread.Sleep(100)
context = ContextWatcher.Menu
End While
'trigger undo
invokeContextMenuItem(context, "Undo")
'Stop watching for context menu
ContextWatcher.untrackContext()
End Sub
Sub invokeContextMenuItem(context As AutomationElement, sMenuItem As String)
'Get context menu children
Dim controls As AutomationElementCollection = context.FindAll(TreeScope.Children, Condition.TrueCondition)
'Loop over controls to find control with name sMenuItem
Dim control As AutomationElement
For Each control In controls
If control.Current.Name = sMenuItem Then
'Invoke control
getInvokePattern(control).Invoke()
Exit Sub
End If
Next
End Sub
'Helper function to get InvokePattern from UI Element
Function getInvokePattern(element As AutomationElement) As InvokePattern
Return element.GetCurrentPattern(InvokePattern.Pattern)
End Function
Public Class ContextWatcher
Public Shared Menu As AutomationElement
Private Shared _EventHandler As AutomationEventHandler
Public Shared Sub trackContext()
_EventHandler = New AutomationEventHandler(AddressOf OnContextOpened)
Automation.AddAutomationEventHandler(AutomationElement.MenuOpenedEvent, AutomationElement.RootElement, TreeScope.Descendants, _EventHandler)
End Sub
Public Shared Sub untrackContext()
Automation.RemoveAutomationEventHandler(AutomationElement.MenuOpenedEvent, AutomationElement.RootElement, _EventHandler)
End Sub
Private Shared Sub OnContextOpened(src As Object, args As AutomationEventArgs)
Console.WriteLine("Menu opened.")
Dim element = TryCast(src, AutomationElement)
If element Is Nothing Then
Return
Else
Menu = element
End If
End Sub
End Class
End Module