Delete columns based on header value VBA - vba

Question

I am trying to delete columns that contain the text "Title" from all the Worksheets. (It could be Title A, Title B, etc.)
I wrote the below, but it's not working... Please enlighten me.
Dim wsh As Worksheet
Dim A As Range
For Each wsh In ActiveWorkbook.Worksheets
Do
Set A = Rows(1).Find(What:="Title", LookIn:=xlValues, lookat:=xlPart)
If A Is Nothing Then Exit Do
A.EntireColumn.Delete
Loop
Next wsh

Answer 1

Since you are looking for "Title A" (as well for only "Title") , you can use the Find in 2 ways:
Add the * wild-card to the searched string, and at the third parameter have xlWhole Find(What:="Title*", LookIn:=xlValues, lookat:=xlWhole)
Don't use the * wild-card, and use xlPart .Find(What:="Title", LookIn:=xlValues, lookat:=xlPart)
Code
Option Explicit
Sub RemoveTitle()
Dim wsh As Worksheet
Dim A As Range
For Each wsh In ActiveWorkbook.Worksheets
Do
Set A = wsh.Rows(1).Find(What:="Title", LookIn:=xlValues, lookat:=xlPart)
If Not A Is Nothing Then
A.EntireColumn.Delete
End If
Loop While Not A Is Nothing
Next wsh
End Sub

Answer 2

You are not qualifying your range with a sheet so only the active sheet is searched
Sub x()
Dim wsh As Worksheet
Dim A As Range
For Each wsh In ActiveWorkbook.Worksheets
Do
Set A = wsh.Rows(1).Find(What:="Title", LookIn:=xlValues, lookat:=xlPart)
If A Is Nothing Then Exit Do
A.EntireColumn.Delete
Loop
Next wsh
End Sub

Answer 3

You need to specify the sheet in which you use Find
And add * (wildcard) to include all possibilities
Dim wsh As Worksheet
Dim A As Range
For Each wsh In ActiveWorkbook.Worksheets
Do
Set A = wsh.Rows(1).Find(What:="Title*", LookIn:=xlValues, lookat:=xlPart)
If A Is Nothing Then Exit Do
A.EntireColumn.Delete
Loop
Next wsh

Answer 4

you may want to delete all columns in one shot
Option Explicit
Sub main()
Dim wsh As Worksheet
Dim A As Range, foundTitle As Range
Dim firstAddress As String
For Each wsh In ActiveWorkbook.Worksheets
With wsh.Range("A1", wsh.Cells(1, wsh.Cells.Columns.Count).End(xlToLeft))
Set foundTitle = .Offset(1).Resize(1, 1)
Set A = .Find(What:="Title", LookIn:=xlValues, lookat:=xlPart)
If Not A Is Nothing Then
firstAddress = A.Address
Do
Set foundTitle = Union(foundTitle, A)
Set A = .FindNext(A)
Loop While A.Address <> firstAddress
End If
Set foundTitle = Intersect(foundTitle, .Cells)
If Not foundTitle Is Nothing Then foundTitle.EntireColumn.Delete
End With
Next wsh
End Sub