Conditional Formatting Applying to a range instead of the individual cell - vba

Question

The following code is intended to format the cell
if the value entered is No and
If the value of the cell in same row and some columns before is listed in the sshDevices array
Function sshProblem(rng As Range) As Boolean
Dim portStatus As String
portStatus = rng.Value
Dim deviceType As String
deviceType = Cells(ActiveCell.Row, 3).Value
Dim sshDevices As Variant
sshDevices = Array("linux", "vmw", "docker", "unix")
If StrComp(portStatus, "No") = 0 Then
If StrComp(deviceType, sshDevices(1)) = 0 Then
sshProblem = True
End If
End If
End Function
For now I'm just comparing the value of deviceType against the second element in the array. The formatting is working properly if the device type matches and if the content is No. The problem is that when the content is No and the device type does not match, ALL of the cells in the column loose their format. For example:
I enter "No" in row 8 and the cell is properly formatted with pink background:
Then I do the same with columns 9 and 10:
But when I get to 10, I enter "No" in the cell but now the value of previous cell "ubuntu" does not match the value of position 1 of the array, so i would expect that cell not to have a pink background, however all previous cells loose their background when I enter "No":
The conditional formatting settings look like this (the column letter is 'I'):
I dont know if my problem is stating (rng As Range) or if it is the way I set up the conditional formatting rule. Ideas?

Answer 1

If sshProblem is in a regular module then any Cells/Range will refer by default to the ActiveSheet, not necessarily the sheet you're calling the function from.
Also, ActiveCell is no use here - if you want to reference the cell from where the formula is being called, use Application.Caller
Finally, you can use Application.Match to test if a value is contained in an array.
Function sshProblem(rng As Range) As Boolean
Dim portStatus As String, sht As WorkSheet
Dim rw as Long
Set sht = rng.WorkSheet
portStatus = rng.Value
Dim deviceType As String
rw = Application.Caller.Row
deviceType = sht.Cells(rw, 3).Value
Dim sshDevices As Variant
sshDevices = Array("linux", "vmw", "docker", "unix")
If StrComp(portStatus, "No") = 0 Then
sshProblem = Not IsError(Application.Match(deviceType, sshDevices, 0))
End If
End Function