Dynamically Reference a Module Variable - vba

Question

Simple Version:
Module A has a Public variable X
I want to be able to get the value of X from Module B, without hardcoding the name 'Module A', i.e. (obviously this is not the right code):
MsgBox Modules("Module A").X
More Advanced Version:
I have an Add-In/XLSM (it can toggle itself) called TAAA.xlsm. I use Rob Bovey's error handling system, and want to improve/expand it.
A lot of my modules create new workbooks. If the user receives an error, I want to give them the option of sending me the error to examine myself. I'd like it to prompt the user, and if they say 'yes', the error handler would use Outlook to e-mail me:
Error Log
TAAA.xlsm
Any child workbooks related to the error
My plan was to have a Public Workbook Array for each module where it would store any workbooks created/used by the code that caused the error. That way when the error handler processes, it can access that public array in order to attach the workbooks.
I suppose a "simpler" solution would be to store this data on worksheet in TAAA, though it's not as elegant.
Any thoughts would be much appreciated!
EDIT
I solved my own problem in an Answer below. However, I'm still curious if there is a good answer to my original question or if that's impossible.

Answer 1

So in retrospect, the answer seems pretty obvious to me.
How does the central error handler know which module the error came from? By the private module name string being passed to the central error handler.
Likewise, I can just pass the workbook array as another parameter to the central error handler!
So instead of the central error handler looking like this:
Public Function bCentralErrorHandler( _
ByVal sModule As String, _
ByVal sProc As String, _
Optional ByVal sFile As String, _
Optional ByVal bEntryPoint As Boolean) As Boolean
Static sErrMsg As String
Dim iFile As Integer
Dim lErrNum As Long
Dim sFullSource As String
Dim sPath As String
Dim sLogText As String
' Grab the error info before it's cleared by
' On Error Resume Next below.
lErrNum = Err.Number
' If this is a user cancel, set the silent error flag
' message. This will cause the error to be ignored.
If lErrNum = glUSER_CANCEL Then sErrMsg = msSILENT_ERROR
' If this is the originating error, the static error
' message variable will be empty. In that case, store
' the originating error message in the static variable.
If Len(sErrMsg) = 0 Then sErrMsg = Err.Description
' We cannot allow errors in the central error handler.
On Error Resume Next
' Load the default filename if required.
If Len(sFile) = 0 Then sFile = ThisWorkbook.Name
' Get the application directory.
sPath = ThisWorkbook.Path
If Right$(sPath, 1) <> "\" Then sPath = sPath & "\"
' Construct the fully-qualified error source name.
sFullSource = "[" & sFile & "]" & sModule & "." & sProc
' Create the error text to be logged.
sLogText = " " & Application.UserName & sFullSource & ", Error " & _
CStr(lErrNum) & ": " & sErrMsg
' Open the log file, write out the error information and
' close the log file.
iFile = FreeFile()
Open sPath & msFILE_ERROR_LOG For Append As #iFile
Print #iFile, Format$(Now(), "mm/dd/yy hh:mm:ss"); sLogText
If bEntryPoint Then Print #iFile,
Close #iFile
' Do not display or debug silent errors.
If sErrMsg <> msSILENT_ERROR Then
' Show the error message when we reach the entry point
' procedure or immediately if we are in debug mode.
If bEntryPoint Or gbDEBUG_MODE Then
Application.ScreenUpdating = True
MsgBox sErrMsg, vbCritical, gsAPP_NAME
' Clear the static error message variable once
' we've reached the entry point so that we're ready
' to handle the next error.
sErrMsg = vbNullString
End If
' The return vale is the debug mode status.
bCentralErrorHandler = gbDEBUG_MODE
Else
' If this is a silent error, clear the static error
' message variable when we reach the entry point.
If bEntryPoint Then sErrMsg = vbNullString
bCentralErrorHandler = False
End If
End Function
I would change the definition to:
Public Function bCentralErrorHandler( _
ByVal sModule As String, _
ByVal sProc As String, _
Optional ByVal wbChildWorkbooks() As Workbook, _
Optional ByVal sFile As String, _
Optional ByVal bEntryPoint As Boolean) As Boolean
Fairly obvious in retrospect. Sorry for the wasted question.