copy paste from userform - vba

Question

I have made a userform. It contains around about 19 combo boxes. Combo boxes have 2 options YES and NO. then comes a text box infront of each combo box, where comments are typed. What I want is that if user selects no from combo box I want to copy paste the comments of that combo box from userform onto another excel sheet. Right now I am copy pasting all comments. So I want to add this feature as well. Below is the code I am currently using. Can anybody help me in upgrading this code, to add above mentioned feature as well.
Private Sub ()
Dim ws As Worksheet
Set ws = Worksheets("PQCILDMS")
Dim newRow2 As Long
newRow2 = Application.WorksheetFunction.CountA(ws.Range("A:A")) + 1
ws.Cells(newRow2, 1).Value = cmbDMS.Value
Dim newRow3 As Long
newRow3 = Application.WorksheetFunction.CountA(ws.Range("A:A")) + 1
ws.Cells(newRow3, 1).Value = cmbYesNo.Value
Dim newRow4 As Long
newRow4 = Application.WorksheetFunction.CountA(ws.Range("A:A")) + 1
ws.Cells(newRow4, 1).Value = Me.txtComments.Value
ws.Cells(newRow4, 1).Columns.AutoFit
End Sub

Answer 1

I want to copy paste the comments of that combo box from userform
I think you mean copy TextBox comments?
The best way to handle this is name your ComboBoxes as ComboBox1, ComboBox2..ComboBox19. Similarly for the TextBoxes, name them as TextBox1, textBox2... TextBox19. Ensure that TextBox1 is in front of ComboBox1 and so on.
The reason we do this is so that it become easier to loop. See this example
Private Sub CommandButton1_Click()
Dim ws As Worksheet
Dim lRow As Long, i As Long
'~~> Change this to the relevant sheet
Set ws = Sheet1
With ws
lRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
For i = 1 To 19
If Me.Controls("ComboBox" & i).Value = "No" Then
.Cells(lRow, 1).Value = Me.Controls("TextBox" & i).Value
lRow = lRow + 1
End If
Next i
End With
End Sub

Answer 2

as an alternative to appropriately renaming texboxes and comboboxes facing each other (suggested approach), you could get the textbox facing a given combobox by checking whether textbox horizontal axis (e.g.: its medium ordinate in the Userfom layout) crosses the combobox
so you could put the following code into your userfom code pane:
Option Explicit
Dim Cbs As Collection '<--| set this collection as Userform scoped variable
Dim Tbs As Collection '<--| set this collection as Userform scoped variable
Private Sub CommandButton1_Click()
Dim cb As MSForms.ComboBox, tb As MSForms.TextBox
Dim el As Variant
With Worksheets("PQCILDMS") '<--| reference sheet
For Each el In Cbs '<--|loop through all userform comboboxes
Set cb = el '<--|set the current combobox control
If cb.value = "NO" Then '<--|if its value is "NO" ...
Set tb = GetTbNextToCb(cb, Tbs) '<--|... look for the textbox whose horizontal axis is inbetween the current combobox
If Not tb Is Nothing Then .Cells(.Rows.Count, 1).End(xlUp).Offset(1).value = tb.value '<--|... if found it then write its content in referenced sheet column "A" next available cell
End If
Next el
End With
End Sub
Function GetTbNextToCb(cb As MSForms.ComboBox, Tbs As Collection) As MSForms.TextBox
Dim tb As MSForms.TextBox
Dim cbYMin As Long, cbYMax As Long, tbYMin As Long, tbYMax As Long
Dim el As Variant
GetYMinMax cb, cbYMin, cbYMax '<--| get minimum and maximum ordinate of passed combobox
For Each el In Tbs '<--|loop through all userform textboxes
Set tb = el '<--|set the current textbox control
If IsAxisInBetween(tb, cbYMin, cbYMax) Then '<--|if current textbox horizontal axis inbetween passed combobox minimum and maximum ordinates...
Set GetTbNextToCb = tb '...return the found textbox...
Exit Function '<--|... and exit function (no need to iterate over remaining textboxes)
End If
Next el
End Function
Function IsAxisInBetween(ctrl As Control, yMinRef As Long, yMaxRef As Long) As Boolean
Dim yMin As Long, yMax As Long
GetYMinMax ctrl, yMin, yMax '<--| get minimum and maximum ordinates of the control in the userform
IsAxisInBetween = (yMax + yMin) / 2 <= yMaxRef And (yMax + yMin) / 2 >= yMinRef '<--| check if the control orizontal axis is in between the reference ordinates
End Function
Sub GetYMinMax(ctrl As Control, yMin As Long, yMax As Long)
With ctrl
yMin = .Top '<--| get the minimum ordinate of the control in the Userform
yMax = .Top + .Height '<--| get the maximum ordinate of the control in the Userform
End With
End Sub
'this sub will run at Userfom loading
Private Sub UserForm_Initialize()
Set Cbs = GetCtrls("ComboBox") '<--| gather all Userform comboboxes in this collection
Set Tbs = GetCtrls("TextBox") '<--| gather all Userform texboxes in this collection
End Sub
Function GetCtrls(ctrlTypeName As String) As Collection
Dim coll As New Collection '<--| declare and set a new Collection object
Dim ctrl As Control
For Each ctrl In Me.Controls '<--| loop through all Userform controls
If TypeName(ctrl) = ctrlTypeName Then '<--| if it matches the passed Type name...
coll.Add ctrl, ctrl.Name '<--| ... then add it to the collection
End If
Next ctrl
Set GetCtrls = coll '<--| return the collection
End Function