Walking Through Flagged Cells Individually - vba

Question

I have a stretch goal for my project that goes way beyond my current ability, but I was hoping someone here could put me on the right track. I have the following code:
Public ErrorCount As Integer
Sub GeneralFormat()
ErrorCount = 0
VLookup
MacroFillAreas
color
NonZeroCompare
MustBe
MsgBox ("Number of Errors" & CStr(ErrorCount))
End Sub
I also have the following section of the code:
Sub NonZeroCompare()
Dim i As Long
For i = 5 To 1000 Step 1
If Range("AK" & i).Value = "On" Then
If Range("AL" & i).Value = 0 And Range("AM" & i).Value = 0 Then
Range("AL" & i, "AM" & i).Interior.ColorIndex = 6
ErrorCount = ErrorCount + 1
End If
ElseIf Range("BC" & i).Value = 0 And Range("BD" & i).Value = 0 Then
Range("BC" & i, "BD" & i).Interior.ColorIndex = 6
ErrorCount = ErrorCount + 1
ElseIf Range("EJ" & i).Value = "On" Then
If Range("EK" & i).Value = 0 And Range("EL" & i).Value = 0 Then
Range("EK" & i, "EL" & i).Interior.ColorIndex = 6
ErrorCount = ErrorCount + 1
End If
ElseIf Range("ES" & i).Value = 0 And Range("ET" & i).Value = 0 Then
Range("ES" & i, "ET" & i).Interior.ColorIndex = 6
ErrorCount = ErrorCount + 1
ElseIf Range("FG" & i).Value = 0 And Range("FH" & i).Value = 0 Then
Range("FG" & i, "FH" & i).Interior.ColorIndex = 6
ErrorCount = ErrorCount + 1
End If
Next i
End Sub
My desired effect is to have the user be able to jump to each cell that contributes to "ErrorCount". There are thousands of cells in my workbook to manage, so being able to jump to the error on review would be great. It would be even better if it could be done with one key on the keyboard, but a button would work too.
Any ideas on how to execute something like this? Also, difficulty level? Any resources on where to begin on this type of feature? Last question: Any native features to excel that I can code in to use that won't require hardcore coding?

Answer 1

Here's an approach that could work in your to handle your requirements.
First, instead of holding only a count of the number of errors, we can hold a Dictionary object that holds references to the cell locations. Using this object, we can then inspect it for a total count of errors, locations, etc.
I'm going to show one (relatively simple) implementation below. (If you're unfamiliar with Dictionary objects, do some research. Basically, it holds a unique key and a corresponding value). In my case, I chose to store the address of an error cell as the key, and I just stored a blank string as the value.
First, I wrote a function to return the dictionary object holding the errors. In the simple implementation, I had a fixed range, and I stored in the address of any cell that had text 'Abc'.
Next, I wrote a helper function that returns a count of the number of objects (this is simple enough that you don't really need a helper function, but it might simplify things if making multiple calls or if you will add more customized logic).
Finally, two subroutines accomplish the final req: traversing through the errors. The first routine 'TraverseErrorsgoes through the dictionary and "visits" each of the addresses. This then yields to aDoEventscall which allows the user to do what they need to. TheJumpAhead` routine tells the system that the user is all finished.
It is helpful to attach a keyboard shortcut to the JumpAhead method. To do so, while in the Excel workbook, press ALT + F8 to open up the macro window. Select the JumpAhead routine, then click the Options button in the dialog box. This allows you to enter a letter that when pressed along with the CTRL key, runs the macro. (I selected the letter e, so CTRL + e allows me to jump ahead once I've made the changes).
There are some challenges to consider. For example, my cell addresses do NOT have a reference sheet. Therefore, if this macro switches worksheets, you may run into some trouble.
Let me know of any questions.
Dim oDictCellsWithErrors As Object
Dim bContinue As Boolean
Private Function GetErrorsDict() As Object
Dim rData As Range
Dim rIterator As Range
'This helper function returns the dictionary object containing the errors
'If it's already been populated
'If not, it creates then returns the object
If Not oDictCellsWithErrors Is Nothing Then
Set GetErrorsDict = oDictCellsWithErrors
Exit Function
End If
'Some logic to create a dictionary of errors
'In my case, I'm adding all cells that have the text "Abc"
'Your logic should differ
Set rData = Sheet1.Range("A2:A15")
Set oDictCellsWithErrors = CreateObject("Scripting.Dictionary")
For Each rIterator In rData
If rIterator.Value = "Abc" Then
If Not oDictCellsWithErrors.exists(rIterator.Address) Then
oDictCellsWithErrors(rIterator.Address) = ""
End If
End If
Next rIterator
Set GetErrorsDict = oDictCellsWithErrors
End Function
Private Function CountErrors() As Integer
'This function returns the number of errors in the document
CountErrors = GetErrorsDict().Count
End Function
Sub TraverseErrors()
Dim oDict As Object
Dim sKey As Variant
Set oDict = GetErrorsDict()
For Each sKey In oDict.keys
bContinue = False
Sheet1.Range(sKey).Activate
Do Until bContinue
DoEvents
Loop
Next sKey
MsgBox "No more errors"
End Sub
Sub JumpAhead()
bContinue = True
End Sub