Any other method to solve "automation error" - vba

Question

I was able to successfully complete (with so much help from a stack exchange user) a macro to automatically mail merge a word document from excel. But the problem now is, unless the word document is open, I get an automation error.
Right now, I solve it by just opening the word document every time, but I doubt that is the right programming method.
Any suggestions to overcome this error? I am very new to VBA. This is part of my student assignments. Any advise or code changes to help overcome this error? I read the official msdn docs, did not understand a thing. :'(
The error is usually "automation error - with a cross sign" or this one:
http://imgur.com/a/zitah
For both these errors, solution so far was to open the word document first and then run macro.
Update:
I removed "on error..." part and now the error is this:
http://imgur.com/a/epmGR
The program is as follows:
Const wdFormLetters = 0, wdOpenFormatAuto = 0
Const wdSendToNewDocument = 0, wdDefaultFirstRecord = 1, wdDefaultLastRecord = -16
Sub RunMerge2()
Dim wd As Object, wdocSource As Object
Dim sh As Worksheet
Dim Lrow As Long, i As Long
Dim cdir As String, client As String, newname As String
Dim sSQL As String
cdir = "C:\Users\Kamlesh\Desktop\"
On Error Resume Next
Set wd = GetObject(, "Word.Application")
If wd Is Nothing Then
Set wd = CreateObject("Word.Application")
End If
On Error GoTo 0
Set wdocSource = wd.Documents.Open(cdir & "\master\installers.docx")
Set sh = ActiveSheet
strWorkbookName = ThisWorkbook.Path & "\" & ThisWorkbook.Name
With sh
Lrow = .Range("A" & .Rows.Count).End(xlUp).Row
For i = 2 To Lrow
If Len(Trim(.Range("A" & i).Value)) <> 0 Then
client = .Cells(i, 1).Value
newname = "Installer Instructions - " & client & ".docx"
wdocSource.MailMerge.MainDocumentType = wdFormLetters
'~~> Sample String
sSQL = "SELECT * FROM `Sheet1$` WHERE [Client Name] = '" & .Range("A" & i).Value & "'"
wdocSource.MailMerge.OpenDataSource Name:=strWorkbookName, _
AddToRecentFiles:=False, Revert:=False, Format:=wdOpenFormatAuto, _
Connection:="Data Source=" & strWorkbookName & ";Mode=Read", _
SQLStatement:=sSQL
With wdocSource.MailMerge
.Destination = wdSendToNewDocument
.SuppressBlankLines = True
With .DataSource
.FirstRecord = wdDefaultFirstRecord
.LastRecord = wdDefaultLastRecord
End With
.Execute Pause:=False
End With
wd.ActiveDocument.SaveAs cdir & newname
wd.ActiveDocument.Close SaveChanges:=False
End If
Next i
End With
wdocSource.Close SaveChanges:=False
'wd.Quit
Set wdocSource = Nothing
Set wd = Nothing
End Sub

Answer 1

this line
Set wdocSource = wd.Documents.Open(cdir & "\master\installers.docx")
should be
Set wdocSource = wd.Documents.Open(cdir & "master\installers.docx")
and
strWorkbookName = ThisWorkbook.Path & "\" & ThisWorkbook.Name
can be replaced with
strWorkbookName = ThisWorkbook.FullName
To find what part of the code is causing the error, in Tools > Options > Editor tab check everything
(source: windows.net)
and in the General tab check everything and select Break in Class Module
(source: s-msft.com)
.aspx#odc_ac2007_ta_ErrorHandlingAndDebuggingTipsForAccessVBAndVBA_BasicErrorHandling)