list of class with members from derived class - vb.net

Question

I'd like to create list of class of different devices with its designed members. It this possible?
Public lstDevices As New List(Of Device)
Public Class Device
Public strName As String
Public iKind As Integer
End Class
Then I'll have particular kind of Device named Printer
Public Class Printer : Inherits Device
public shared iAge as integer
End Class
How can I reach for ex.
lstDevices.Find(Function(p) p.strName = strName).iAge = 10
if I make clsPrinter = new Printer()
I can reach clsPrinter.iAge
But with list, is this possible?

Answer 1

The lstDevices-list stores Devices, so the parent class of Printer which has the iAge property. You have to cast it appropriately. But you also have to store the result of List.Find in a variable:
Dim foundDevice As Device = lstDevices.Find(Function(p) p.strName = strName)
If foundDevice IsNot Nothing AndAlso TypeOf foundDevice Is Printer Then
Dim foundPrinter As Printer = DirectCast(foundDevice, Printer)
foundPrinter.iAge = 10
End If
Another nice LINQ approach is:
Dim foundPrinters = From p In lstDevices.OfType(Of Printer)()
Where p.strName = strName
Dim firstPrinter As Printer = foundPrinters.FirstOrdefault()

Answer 2

I just want to remind you that iAge property of Printer class is a shared property.
I prefer the LINQ methods over LINQ queries. So I tried converting Tim's query to LINQ method (minus the where criteria). I intentionally use First() instead of FirstOrDefault(). Code looks like this:
Module Module1
Public lstDevices As New List(Of Device)
Sub Main()
lstDevices.Add(New Printer() With {.strName = "Epson", .iKind = 1})
lstDevices.Add(New Printer() With {.strName = "HP", .iKind = 2})
lstDevices.OfType(Of Printer).First().iAge = 10
Console.WriteLine(lstDevices.OfType(Of Printer).First().iAge)
Console.ReadKey(True)
End Sub
End Module
Public Class Device
Public strName As String
Public iKind As Integer
End Class
Public Class Printer : Inherits Device
Public Shared iAge As Integer
End Class
VS shows warnings in these lines:
lstDevices.OfType(Of Printer).First().iAge = 10
Console.WriteLine(lstDevices.OfType(Of Printer).First().iAge)
The warning for both lines is:
Access of shared member, constant member, enum member or nested type
through an instance; qualifying expression will not be evaluated.
It means that the expression won't be evaluated because iAge is a shared property. Even if I remove the 2 lines where I add Printer instances to the list, the code won't throw any exception. That's because iAge property is tied to the Printer class, not instance of Printer class.
Sub Main()
'lstDevices.Add(New Printer() With {.strName = "Epson", .iKind = 1})
'lstDevices.Add(New Printer() With {.strName = "HP", .iKind = 2})
' these 2 lines won't throw any exceptions eventhough the list is empty
lstDevices.OfType(Of Printer).First().iAge = 10
Console.WriteLine(lstDevices.OfType(Of Printer).First().iAge)
Console.ReadKey(True)
End Sub
So there 2 lines can be simplified to:
'lstDevices.OfType(Of Printer).First().iAge = 10
'Console.WriteLine(lstDevices.OfType(Of Printer).First().iAge)
Printer.iAge = 10
Console.WriteLine(Printer.iAge)
If you remove the Shared keyword from iAge, then the code might throw exception if the list if empty. Tim's code is safe because he use FirstOrDefault(), you can check whether firstPrinter is nothing (null) or not, then use the iAge property.