Excel VBA Collection to Validation List - vba

Question

I am fairly new to VBA, but I am decently experienced with Java and Python. I was given the task of organizing a nearby school's grading standards on an excel spreadsheet, and I wanted to give the teachers the option to reorganize the spreadsheet at the click of a button, so I have decided to use VBA.
This is what I have so far for my code (it's sloppy, but I will clean it up once I get it working well):
Private Sub Workbook_Open()
' Initialize Variables
Dim i%, j%
Dim vTemp$, StdList$
Dim Stds As Collection
Set Stds = New Collection
' Compute the index of the last Standard on Test worksheet
lastStd = Sheet3.Range("B" & Rows.Count).End(xlUp).Row
' Remove Duplicates from the Standards and remove commas
On Error Resume Next
For i = 2 To lastStd
Stds.Add (Sheet3.Cells(i, 2)), Chr(34) & (Sheet3.Cells(i, 2)) & Chr(34)
Next i
On Error GoTo 0
For i = 1 To Stds.Count
Stds.Item(i) = Replace(Stds.Item(i), ",", Chr(130))
Next i
' Sort the Standards Alphabetically (using Bubble Sort)
For i = 1 To Stds.Count - 1
For j = i + 1 To Stds.Count
If Stds(i) > Stds(j) Then
vTemp = Stds(j)
Stds.Remove (j)
Stds.Add vTemp, vTemp, i
End If
Next j
Next i
' Reinitialize Cell Data
Sheet8.Range("A1:J100").Clear
For i = 1 To Stds.Count
Sheet8.Cells(i, 1).Value = Stds.Item(i)
Next i
' Output the Standards to the Excel Spreadsheet
For i = 1 To Stds.Count
StdList = StdList & Stds.Item(i) & ","
Next i
With ThisWorkbook.Sheets("Sheet1").Range("F3").Validation
.Delete
.Add Type:=xlValidateList, _
AlertStyle:=xlValidateAlertStop, _
Formula1:=StdList
End With
End Sub
The code executes when I open up the spreadsheet, but I get "Run Time Error 1004 'Application Defined or Object Defined Error'" upon execution. The goal is to have the code search through the grading standards, enumerate a collection, remove the duplicates, sort the standards alphabetically, and replace the commas with a character that looks like a comma so that I can convert the collection to a list and place that list into a drop down list somewhere on the spreadsheet. When I select the debug option, these three lines are highlighted:
.Add Type:=xlValidateList, _
AlertStyle:=xlValidateAlertStop, _
Formula1:=StdList
My guess is that I am either struggling with the syntax, or there is a type mismatch somewhere in there that I am not seeing; both of which are likely.

Answer 1

You can run debug.print on your parameters - that would point out that xlValidateAlertStop was empty
It should actually be xlValidAlertStop

Answer 2

Another solution to avoide one loop is to use Scripting.Dictionary object
Sub SubDicList()
'With a CD's Collection DataBase
'|Group And singer |Album Title| Date| Price| Qty | Web Link|
'MainList is DataField of Group and singer
'SubList is The Dropdown Validation List to get from DataField of Album TiTle
Dim ws As Worksheet, nRow As Long, i As Integer
Dim MainList As Range, MainData As Range, DataSelected As Variant
Dim SubList As String, SubData As Variant
Dim Dic As Object
Set Dic = CreateObject("Scripting.Dictionary")
Set ws = Worksheets("Data")
DataSelected = Range("K4") 'Data validation from a dropdown list with MainList Content
nRow = ws.Cells(2 ^ 20, 2).End(xlUp).Row 'Last row
Set MainList = ws.Range(ws.Cells(5, 2), ws.Cells(nRow, 2)) 'MainList as Range (Group and Singers)
For Each MainData In MainList
If MainData.Value = DataSelected Then
SubData = MainData.Offset(0, 1) 'SubData is Album Title of Group and singers
If Not Dic.Exists(SubData) Then 'If Album Title is not in the Sripting Dictionary
Dic.Add SubData, CStr(SubData) 'Add Allbum Titel to the Sripting Dictionary
SubList = SubList & SubData & "," 'Prepare the Validation List for each step of loop
End If
End If
Next MainData
With Range("L4").Validation 'Range("L4"): Where to put the Data Validation Dropdown List
.Delete
.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
xlBetween, Formula1:=SubList
.IgnoreBlank = True
.InCellDropdown = True
.InputTitle = ""
.ErrorTitle = ""
.InputMessage = ""
.ErrorMessage = ""
.ShowInput = True
.ShowError = True
End With
Set Dic = Nothing
Set MainList = Nothing
Set ws = Nothing
End Sub