SAS, variables order in data import - variables

Question

I've searched my problem in a lot of topics, but no solutions yet.
My SAS code import data from a .txt file, the problem is that the order of variables changes from a version to another (so I have to changes it back to fit my code otherwise it crushes). Here's the code importing data:
data Donnees1 ;
%let _EFIERR_ = 0; /* set the ERROR detection macro variable */
infile "&source\Donnees\&data1" delimiter='09'x MISSOVER DSD
lrecl=32767 firstobs=2 ;
informat Numero $100. ;
informat NU_CLI $100. ;
informat Date $100.;
informat Code $10. ;
informat RESEAU $100.
informat TOP_SAN $10. ;
informat TOP_PRV $10. ;
format Numero $100. ;
format NU_CLI $100. ;
format Date $100.;
format Code $10. ;
format RESEAU $100.
format TOP_SAN $10. ;
format TOP_PRV $10. ;
input
Numero
NU_CLI
Date
Code
RESEAU
TOP_SAN
TOP_PRV;
if _ERROR_ then call symput('_EFIERR_',1); /* set ERROR detection macro variable */
run;`
I am looking for an option so that, if the variables changes order in the source file, it doesn't make my code crush.
I've seen solution to reorder variables with retain, but it's for changing order of variables already imported, not during the import step.
The code works perfectly with no issues, only if the data source changes in term of variables order.
Thank you for your help.

Answer 1

IF the variables are named in your text file you could use PROC IMPORT's GETNAMES option to get SAS to automatically name your variables. This doesn't provide you with as much granular control as datastep infile but should work as long as your input file isn't too irregular.

Answer 2

You should also change the order of variables in input list in data-step.

Answer 3

If the variable names and attributes do not change then you can dynamically generate the INPUT statement by reading the variable names from the header row of the file. Read the header line and generate a macro variable.
data _null_;
infile "&source\Donnees\&data1" obs=1;
input;
call symputx('varnames',translate(_infile_,' ','09'x));
run;
Then read the data lines into a dataset and use the variable list in the INPUT statement. You actually don't want to use the ugly code that PROC IMPORT creates. Do NOT attach $xx FORMATS and INFORMATS to character variables as they add no value and can cause trouble down the line if they get out of sync with the actual length of the variable.
data Donnees1;
infile "&source\Donnees\&data1" dlm='09'x TRUNCOVER DSD lrecl=32767 firstobs=2 ;
length
Numero $100
NU_CLI $100
Date $100
Code $10
RESEAU $100
TOP_SAN $10
TOP_PRV $10
;
input &varnames ;
run;

Answer 4

I have found a solution but haven't tested it yet : Creating a temporary Work table where I import all the variables (the order doesn't matter) through a proc import. Then I create a data step where I keep only the variables that interest me, and this time in the correct order. I'll tell you if it works fine.
Also Tom's solution seems pretty good, I'll give it a shot.
Thank you for your help.