Saving Outlook Attachement with password then forward - vba

Question

I need to build a rule script that saves an outlook attachment (excel specific) to a the user's hard drive. I then need to add a password to this excel attachment and then forward it.
Saving and forwarding emails/attachments is simple enough using the VBA Outlook developer tools (see below). However, I am running into issues with adding a password to this attachment. Is this possible or do I need an outside script/program to do this task? Furthermore, do you have any other suggestions?
Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
saveFolder = "c:\"
For Each objAtt In itm.Attachments
objAtt.SaveAsFile saveFolder & "\" & objAtt.DisplayName
Set objAtt = Nothing
Next
Call SendEmail
End Sub
Public Sub SendEmail()
Dim olApp As Outlook.Application
Dim olMail As Outlook.MailItem
Dim blRunning As Boolean
'get application
blRunning = True
On Error Resume Next
Set olApp = GetObject(, "Outlook.Application")
If olApp Is Nothing Then
Set olApp = New Outlook.Application
blRunning = False
End If
On Error GoTo 0
Set olMail = olApp.CreateItem(olMailItem)
With olMail
.Subject = "My email with attachment"
.Recipients.Add "jlanz#mmyemail.com"
.Attachments.Add "C:\test123.xlsx"
.Body = "Here is an email"
.Send
End With
If Not blRunning Then olApp.Quit
Set olApp = Nothing
Set olMail = Nothing
End Sub

Answer 1

As per my comment you need to add a reference to the excel library. Then you can set a password using the example below.
Sub ProtectExcelWorkbook(filePath As String)
Dim pw As String
pw = "password"
Dim eApp As Excel.Application
Dim eBook As Excel.Workbook
Set eApp = New Excel.Application
Set eBook = eApp.Workbooks.Open(filePath)
eBook.Password = pw
eBook.Save
Set eBook = Nothing
eApp.Quit
Set eApp = Nothing
End Sub
Public Sub saveAttachtoDisk(itm As Outlook.MailItem)
Dim objAtt As Outlook.Attachment
Dim saveFolder As String
saveFolder = "c:\"
For Each objAtt In itm.Attachments
objAtt.SaveAsFile saveFolder & "\" & objAtt.DisplayName
ProtectExcelWorkbook saveFolder & "\" & objAtt.DisplayName
Set objAtt = Nothing
Next
Call SendEmail
End Sub