Find function within a Do Loop providing inconsistent results - vba

Question

I am trying to test the differences between two lists. My VBA code is supposed to loop through list one and use the find method to look at each item in list two. If the item is not found in list two, I use the copy , paste method to log it in my compare sheet. The code then goes back and does the reverse procedure to test list two on list one; loop through list two and look for each item in list 1.
My Results imply and inconsistent number of matching results. The number of items in list 1 minus the results from the "list1" find loop do not equal number of items in list two minus the number of items from "list2' find loop. The remaining items should only be values that where found in each list.
All items are primary keys and are unique within their respective list.
Public Sub compare_list()
Dim wsList2 As Worksheet
Dim wsList1 As Worksheet
Dim wsCompare As Worksheet
Dim found1 As Range
Set wsList2 = Worksheets("List2")
Set wsList1 = Worksheets("List1")
Set wsCompare = Worksheets("Compare")
Application.ScreenUpdating = False
'Check each value in client_id list one with list two
wsList1.Activate
wsList1.Range("a1").Select
Do Until ActiveCell.Value = ""
Set found1 = wsList2.Range("a1",_
wsList2.Range("A1048576").End(xlUp)).Find(Selection.Value)
If found1 Is Nothing Then
Selection.Copy
wsCompare.Range("A1048576").End(xlUp).Offset(1, 0).PasteSpecial
End If
ActiveCell.Offset(1, 0).Select
Loop
'Check each value in client_id list two with list one
wsList2.Activate
wsList2.Range("a1").Select
Do Until ActiveCell.Value = ""
Set found1 = wsList1.Range("a1",_
wsList1.Range("A1048576").End(xlUp)).Find(Selection.Value)
If found1 Is Nothing Then
Selection.Copy
wsCompare.Range("B1048576").End(xlUp).Offset(1, 0).PasteSpecial
End If
ActiveCell.Offset(1, 0).Select
Loop
wsCompare.Activate
Application.ScreenUpdating = True
End Sub
Just a note: I am very new to VBA, and do not come from a developer back ground. You probably can't dumb down your solution too much.

Answer 1

My problem was a default parameter in the find function. I needed to set the LookAt:=xlWhole
For example, list 1 = (1,2,32,142) and list 2 = (1,2,3,132)
For my purposes 32 is not in list 2 but without setting that parameter the find function returns a result when search for 32 as it finds it in the cell containing 132
The following is the code that is working for me now. Thanks for all your help
Public Sub compare_list()
Dim wsList2 As Worksheet
Dim wsList1 As Worksheet
Dim wsCompare As Worksheet
Dim found1 As Range
Dim found2 As Range
Dim myCell As Range
Dim countList2 As Integer
Dim countList1 As Integer
Dim listDiff As Integer
Dim commonList2 As Integer
Dim commonList1 As Integer
Dim diffList1 As Integer
Dim diffList2 As Integer
Set wsList2 = Worksheets("List2")
Set wsList1 = Worksheets("List1")
Set wsCompare = Worksheets("Compare")
Application.ScreenUpdating = False
Application.CutCopyMode = False
'Check each value in the client_id list created by List1 to find an equal value in List2's list
Set myCell = wsList1.Range("A1")
Do Until myCell.Value = ""
Set found1 = wsList2.Range("a1", wsList2.Range("A1048576").End(xlUp)).Find(what:=myCell.Value, LookAt:=xlWhole)
If found1 Is Nothing Then
myCell.Copy
wsCompare.Range("A1048576").End(xlUp).Offset(1, 0).PasteSpecial
Else
myCell.Copy
wsCompare.Range("G1048576").End(xlUp).Offset(1, 0).PasteSpecial
End If
Set myCell = myCell.Offset(1, 0)
Loop
'Check each value in the client_id list created by List2 to find an equesl value in List1's list
Set myCell = wsList2.Range("A1")
Do Until myCell.Value = ""
Set found2 = wsList1.Range("a1", wsList1.Range("A1048576").End(xlUp)).Find(what:=myCell.Value, LookAt:=xlWhole)
If found2 Is Nothing Then
myCell.Copy
wsCompare.Range("B1048576").End(xlUp).Offset(1, 0).PasteSpecial
Else
myCell.Copy
wsCompare.Range("F1048576").End(xlUp).Offset(1, 0).PasteSpecial
End If
Set myCell = myCell.Offset(1, 0)
Loop
Application.ScreenUpdating = True
wsCompare.Activate
'test logic of result
countList1 = wsList1.Range("a2", wsList1.Range("A1048576").End(xlUp)).Rows.count
countList2 = wsList2.Range("a2", wsList2.Range("a1048576").End(xlUp)).Rows.count
diffList1 = (wsCompare.Range("a2", wsCompare.Range("A1048576").End(xlUp)).Rows.count - 1)
diffList2 = (wsCompare.Range("b2", wsCompare.Range("b1048576").End(xlUp)).Rows.count - 1)
listDiff = Abs(countList1 - countList2)
commonList2 = (countList2 - diffList2)
commonList1 = (countList1 - diffList1)
MsgBox "List2 has " & commonList2 & " in common with List1" & vbCrLf & "List1 has " & commonList1 & " in common with List2"
End Sub