Searching for word and finding it's line number LINQ - vb.net

Question

Hey all I found the following code HERE and was wondering if it's possible if I can also get the line number where the word appears by using the LINQ query or by some other means?
Dim startFolder = "C:\Users\me\Documents\Visual Studio 2012\Projects\project"
Dim fileList = New System.IO.DirectoryInfo(startFolder).GetFiles("*.vb", System.IO.SearchOption.AllDirectories)
Dim queryMatchingFiles = From file In fileList _
Where file.Extension = ".vb" _
Let fileText = GetFileText(file.FullName) _
Where fileText.Contains(word2Search) _
Select file.FullName
Debug.Print("The term " & word2Search & " was found in:")
For Each filename In queryMatchingFiles
Debug.Print(filename)
Next
The code works for finding the word but I would really like to be able to know what line it was found on as well.
Any help would be great!

Answer 1

The LINQ Select method has a overload that passes in the index of the item.
Dim startFolder = "C:\Users\me\Documents\Visual Studio 2012\Projects\project"
Dim matches =
From f In Directory.EnumerateFiles(startFolder, "*.vb", SearchOption.AllDirectories)
From l In File.ReadLines(f).Select(Function(x, i) New With { .Line = x, .LineNo = i + 1})
Where l.Line.Contains(word2Search)
Select FileName = f, LineNo = l.LineNo, Line = l.Line
Matches will be an IEnumerable of objects with FileName, LineNo and Line properties.
UPDATE
To get the file name and an array of the matching line indexes, you could do something like this:
Dim matches =
From f In Directory.EnumerateFiles(startFolder, "*.vb", SearchOption.AllDirectories)
From l In File.ReadLines(f).Select(Function(x, i) New With { .Line = x, .LineNo = i + 1})
Where l.Line.Contains(word2Search)
Select File = f, LineNo = l.LineNo
Group By File Into g = Group
Select FileName = File, LineNos = g.Select(Function(x) x.LineNo).ToArray()
This will give you an IEnumerable of objects with FileName and LineNos properties.
Finding the positions of the matches in the lines requires a few more changes, since Contains just returns a Boolean. You can use Regex.Matches to find the positions of matches in the line, so:
Dim matches =
From f In Directory.EnumerateFiles(startFolder, "*.vb", SearchOption.AllDirectories)
From l In File.ReadLines(f).Select(Function(x, i) New With { .Line = x, .LineNo = i + 1})
Where l.Line.Contains(word2Search)
Select File = f, LineNo = l.LineNo,
MatchPositions = Regex.Matches(l.Line, Regex.Escape(word2Search)).Cast(Of Match)().Select(Function(x) x.Index)
Group By File Into g = Group
Select FileName = File, Matched = g.Select(Function(x) New With { x.LineNo, .Positions = x.MatchPositions.ToArray() }).ToArray()
After this, you end up with an IEnumerable of objects with FileName and Matched properties (unfortunately, VB.NET didn't like that being called Matches because that clashes with the matches variable, but you can play with that to your liking). The Matched property is an array of objects with LineNo and Positions properties, with Positions being an array of the indexes into the strings (zero based, so add a + 1 in there if you like).