Syspro - Update query for sales prices - sql

Question

I can't seem to find any information on SQL scripts for Syspro - Google searches just come up with 3rd party software despite Syspro using a fairly standard looking SQL database.
I'm just wondering if anyone on here has any experience with updating Syspro via SQL updates - I have a client that uses Syspro and they've previously updated it by exporting everything into Access, making changes and updating everything from there - I was told by their out-going IT consultant that this is the only way to update Syspro (which, I suspect, isn't true).
Just looking for some do's and dont's before I go screwing up data!
thanks,
Darren

Answer 1

It's not advisable to update the SYSPRO database directly. While it is relatively simple to breakdown and track what data is stored where etc. there is more often than not more than 1 place where a field is updated and/or there is an additional flag that is also changed. Further, updating it directly in the database would also get rid of any possible audit trail.
If this needs to be done in bulk (as your question seems to refer) then this would be best done by posting an update using one of the SYSPRO "business objects". Have a look here for more info regarding business objects: SYSPRO Business Object Library
There are 2 ways you can make use of this: in a custom pane within SYSPRO (no licensing requirements then) or if your customer is licensed for the respective business object you could write an external program to post updates using the business object.
Below is a custom pane I created sometime ago that updates prices of items based on an excel spreadsheet. Save the below code section into a txt file and when in SYSPRO if you click on the drop down arrow (on the top right of any pane) you can select Customized Pane > Import Customized Pane and specify this txt file you have saved. This will create the custom pane with title Pricelist Import. If you now press the refresh button on this customized pane it's going to ask you for an excel file to base it's update on. By default it will look for a file called Pricelist Import.xlsx in the SYSPRO\Base\Settings folder of the machine you are working on. You will need to create a spreadsheet with 5 columns and in this order too (StockCode, PriceCode, SellingPrice, PriceBasis, CommisionCode). Once you have a spreadsheet and specify the file at this prompt it will load the contents of the spreadsheet into the listview and by default all entries will be selected to import. If you now press Update it will update the prices accordingly and if not possible will return the respective error messages back into the listview.
# Customized Panes for 'IMPDH2LZ' Created: 2013/09/17
# PANE:Pricelist Import
[PANE]
CHRISVIMPDH2LZ 01000Pricelist Import 020 000000500001IMPDH2000M000Update 3362 00000 0
[VBSCRIPT]
' This script contains functions for customized pane events.
' You must not modify the name of the functions.
Option Explicit
Public Debug : Debug = "False"
Function CustomizedPane_OnRefresh()
Dim ImportFilePmt : ImportFilePmt = InputBox("Enter Location of Excel file to Import?", "Pricelist Import File", SystemVariables.CodeObject.baseSettingsFolder &"Pricelist Import.xlsx")
Dim objExcel : Set objExcel = CreateObject("Excel.Application")
On error resume next
Dim objWorkbook : Set objWorkbook = objExcel.Workbooks.Open(ImportFilePmt)
If err then
If ImportFilePmt <> "" then
msgbox "Error Importing File: " & vbcrlf & err.Description & vbCrlf & vbCrlf & "Import Cancelled!!", vbCritical, "Error Importing/Opening File"
Exit Function
Else
CustomizedPane_OnLoad
Exit Function
End If
End if
on error Goto 0
Dim objWorksheet : Set objWorksheet = objExcel.Worksheets(1)
objWorksheet.Activate
Dim intRow : intRow = 2
Dim XMLForList
Dim intLinesRow : intLinesRow = 2
XMLForList = "<ImportList>"
Do Until objExcel.Cells(intLinesRow,1).Value = "" or objExcel.Cells(intLinesRow,1).Value = " "
XMLForList = XMLForList & "<Item><StockCode>"& objExcel.Cells(intLinesRow, 1).Value &"</StockCode>"
XMLForList = XMLForList & "<PriceCode>" & objExcel.Cells(intLinesRow,2).Value & "</PriceCode>"
XMLForList = XMLForList & "<SellingPrice>" & objExcel.Cells(intLinesRow,3).Value & "</SellingPrice>"
XMLForList = XMLForList & "<PriceBasis>" & objExcel.Cells(intLinesRow,4).Value & "</PriceBasis>"
XMLForList = XMLForList & "<CommisionCode>" & objExcel.Cells(intLinesRow,5).Value & "</CommisionCode>"
XMLForList = XMLForList & "<Import>1</Import>"
XMLForList = XMLForList & "</Item>"
intLinesRow = intLinesRow + 1
Loop
XMLForList = XMLForList & "</ImportList>"
objExcel.Quit
Dim ListXML
ListXML = ListXML & "<Columns PrimaryNode='Item' Style='DataGrid' AutoSize='true' FreezeColumn='0' >"
ListXML = ListXML & "<Column Name='StockCode' Description='Stock code' />"
ListXML = ListXML & "<Column Name='PriceCode' Description='Price code' />"
ListXML = ListXML & "<Column Name='SellingPrice' Description='Selling price' Type='Numeric' Alignment='Right' HdrAlignment='Right' Decimals='2' />"
ListXML = ListXML & "<Column Name='PriceBasis' Description='Price basis' />"
ListXML = ListXML & "<Column Name='CommisionCode' Description='Commision code' />"
ListXML = ListXML & "<Column Name='Import' Description='Import' Type='checkbox' Editable='true' />"
ListXML = ListXML & "</Columns>"
CustomizedPane.CodeObject.ListviewProperties = ListXML
CustomizedPane.CodeObject.ListviewData = XMLForList
msgbox intLinesRow - 2 & " record/s read",vbInformation,"File Imported"
End Function
Function FileHandle(Action, ActVariable)
Dim Path : Path = SystemVariables.CodeObject.baseSettingsFolder & "ExcelImportPanePath.txt"
Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8
dim fso, ts
Set fso = CreateObject("Scripting.FileSystemObject")
If Action = "WritePath" then
Set ts = fso.CreateTextFile(Path,2,False)
ts.Write (ActVariable)
ts.Close
Elseif Action = "DeletePath" then
Set ts = fso.OpenTextFile(Path,1)
Dim FilePathDP : FilePathDP = ts.ReadAll
ts.Close
fso.DeleteFile FilePathDP
Elseif Action = "ReadPath" then
on error Resume Next
Set ts = fso.OpenTextFile(Path,ForReading)
Dim strLine
Do Until ts.AtEndOfStream
strLine = ts.ReadLine
Loop
ts.close
if Err then
FileHandle = "File Deleted"
Else
FileHandle = strLine
End if
On Error Goto 0
Elseif Action = "Delete" then
On Error Resume Next
fso.DeleteFile Path
If err then
Exit Function
End if
On Error Goto 0
End if
End Function
Function CustomizedPane_OnLoad()
Dim ListXML
ListXML = ListXML & "<Columns PrimaryNode='Notify' Style='DataGrid' AutoSize='true' FreezeColumn='0' >"
ListXML = ListXML & "<Column Name='Note' Description='NOTE' />"
ListXML = ListXML & "</Columns>"
CustomizedPane.CodeObject.ListviewProperties = ListXML
Dim ShowNote
ShowNote = "<Start>"
ShowNote = ShowNote & "<Notify><Note>First Load the Excel File Path...</Note></Notify>"
ShowNote = ShowNote & "</Start>"
CustomizedPane.CodeObject.ListviewData = ShowNote
End Function
Function CustomizedPane_OnToolbarButton1Clicked()
Dim MaxRows : MaxRows = Ubound(CustomizedPane.CodeObject.Array, 2)
If MaxRows = 0 OR CustomizedPane.CodeObject.Array(0,0) = "First Load the Excel File Path..." then
Exit Function
Else
Dim Counter
Dim CLineCounter : CLineCounter = 0
For Counter = 0 to MaxRows - 1
If CustomizedPane.CodeObject.Array(5, Counter) = "1" then
CLineCounter = CLineCounter + 1
End If
Next
If CLineCounter = 0 then
msgbox "There was nothing selected to import.",vbInformation,"Importing..."
Exit Function
Else
msgbox CLineCounter & " record/s to be updated.",vbInformation,"Importing..."
CallINVSPR
End If
End If
End Function
Function CallINVSPR()
dim XMLOut, XMLParam, XMLDoc
XMLParam = "<SetupInvPrice>"
XMLParam = XMLParam & " <Parameters>"
XMLParam = XMLParam & " <IgnoreWarnings>N</IgnoreWarnings>"
XMLParam = XMLParam & " <ApplyIfEntireDocumentValid>Y</ApplyIfEntireDocumentValid>"
XMLParam = XMLParam & " <ValidateOnly>N</ValidateOnly>"
XMLParam = XMLParam & " </Parameters>"
XMLParam = XMLParam & "</SetupInvPrice>"
XMLDoc = " <SetupInvPrice>"
Dim MaxRows : MaxRows = Ubound(CustomizedPane.CodeObject.Array, 2)
Dim Counter
Dim LineCounter : LineCounter = 0
Dim CLineCounter : CLineCounter = 0
For Counter = 0 to MaxRows - 1
If CustomizedPane.CodeObject.Array(5, Counter) = "1" then
XMLDoc = XMLDoc & " <Item>"
XMLDoc = XMLDoc & " <Key>"
XMLDoc = XMLDoc & " <StockCode>" & CustomizedPane.CodeObject.Array(0, Counter) & "</StockCode>"
XMLDoc = XMLDoc & " <PriceCode>" & CustomizedPane.CodeObject.Array(1, Counter) & "</PriceCode>"
XMLDoc = XMLDoc & " </Key>"
XMLDoc = XMLDoc & " <SellingPrice>" & CustomizedPane.CodeObject.Array(2, Counter) & "</SellingPrice>"
XMLDoc = XMLDoc & " <PriceBasis>" & CustomizedPane.CodeObject.Array(3, Counter) & "</PriceBasis>"
XMLDoc = XMLDoc & " <CommissionCode>" & CustomizedPane.CodeObject.Array(4, Counter) & "</CommissionCode>"
XMLDoc = XMLDoc & " </Item>"
CLineCounter = CLineCounter + 1
End If
Next
XMLDoc = XMLDoc & " </SetupInvPrice>"
on error resume next
XMLOut = CallSetup("INVSPR",XMLParam,XMLDoc,"Update","auto")
if err then
msgbox err.Description, vBCritical, "Calling Business Object"
exit function
end if
' Switch on error handling
on error goto 0
'msgbox CLineCounter & " rows updated"
If Debug = "True" then
Dim Path : Path = SystemVariables.CodeObject.baseSettingsFolder & "DEBUGExcelImportPane.txt"
'Output XML to file
dim fso, ts
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.CreateTextFile(Path,2,True)
ts.Write ("XMLIn:" & vbCrlf & XMLDoc & vbCrlf &"XMLParam:" & vbCrlf & XMLParam & vbCrlf &"XMLOut:" & vbCrlf & XMLOut)
ts.Close
msgbox "Debug Done." & vbCrLf & " Check: "& Path
End If
ResultValidate XMLOut, "Update", CLineCounter
End Function
Function ResultValidate(XMLIn, Action, CLineCounter)
Dim XMLDOM : Set XMLDOM = CreateObject("Microsoft.XMLDOM")
XMLDOM.Async = False
XMLDOM.LoadXML(XMLIn)
Dim ListXML
Dim WarningMsgs : Set WarningMsgs = XMLDOM.GetElementsByTagName("ErrorDescription")
Dim StkList
If WarningMsgs.Length > 0 then
StkList = "<List>"
StkList = StkList & "<StockList>"
StkList = StkList & "<Notes>Errors Found: " & WarningMsgs.Length & "</Notes>"
StkList = StkList & "</StockList>"
If WarningMsgs.Length > 0 then
Dim WarnItems
For Each WarnItems in WarningMsgs
StkList = StkList & "<StockList>"
StkList = StkList & "<Notes>Error in : " & WarnItems.ParentNode.NodeName & " - " & WarnItems.PreviousSibling.PreviousSibling.Text & ": " & WarnItems.Text &"</Notes>"
StkList = StkList & "</StockList>"
Next
End If
StkList = StkList & "</List>"
ListXML = "<Columns PrimaryNode='StockList' Style='DataGrid' AutoSize='true' FreezeColumn='0' >"
ListXML = ListXML & "<Column Name='Notes' Description='Notes' Link='false' />"
ListXML = ListXML & "</Columns>"
else
StkList = "<List>"
StkList = StkList & "<StockList>"
StkList = StkList & "<Notes>No Errors Found..." & CLineCounter & " record/s updated</Notes>"
StkList = StkList & "</StockList>"
StkList = StkList & "</List>"
ListXML = "<Columns PrimaryNode='StockList' Style='DataGrid' AutoSize='true' FreezeColumn='0' >"
ListXML = ListXML & "<Column Name='Notes' Description='Notes' Link='false' />"
ListXML = ListXML & "</Columns>"
End If
CustomizedPane.CodeObject.ListviewProperties = ListXML
CustomizedPane.CodeObject.ListviewData = StkList
End Function
Perhaps if they have a test company try it out in there first so you can see what it's doing?
NB: This was done for SYSPRO 6.1 and 7. Minor updates may be required to make this work in other versions.
You can also check out the SYSPRO Forums for help relating to syspro.
Hope this helps.