Set date variable to null - sql

Question

Dim dtIzvrsenja datetime
Private Sub chkDate_CheckedChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles chkDate.CheckedChanged
If Me.chkDate.Checked Then
Me.dtpDate.CustomFormat = "dd.MM.yyyy"
Me.dtpDate.Enabled = True
dtIzvrsenja = dtpdate.value
Else
Me.dtpDate.CustomFormat = " "
Me.dtpDate.Enabled = False
dtIzvrsenja = Nothing
End If
End Sub
Is there any way to set the value of dtIzvrsenja to null if chk is not checked ?
Edit by using the way other mentioned.
{"Nullable object must have a value."}
Dim dtIzvrsenja2 As DateTime? = Nothing
dtIzvrsenja = dtIzvrsenja2

Answer 1

In order to support that, you need to use the generic Nullable(Of Date) type rather than just Date (the VB alias for the DateTime type). Normally, only reference type variables (Class type variables) support null values. Since Date is a value type variable (Structure), it doesn't support null. Nullable(Of T) allows you to wrap any value type and add support for null values to that type.
In VB (as well as C#, by the way), a question mark after any type name is shorthand for making the type nullable. So, Date? is equivalent to Nullable(Of Date). Here's your example code using nullables:
Dim dtIzvrsenja As Date?
Private Sub chkDate_CheckedChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles chkDate.CheckedChanged
If Me.chkDate.Checked Then
Me.dtpDate.CustomFormat = "dd.MM.yyyy"
Me.dtpDate.Enabled = True
dtIzvrsenja = dtpdate.value
Else
Me.dtpDate.CustomFormat = " "
Me.dtpDate.Enabled = False
dtIzvrsenja = Nothing
End If
End Sub
However, the confusing thing about Nullable(Of T) is that it, itself, is not a reference type. Nullable(Of T) is a value type. So, even Nullable(Of Date) variables cannot be set to null in the traditional sense. What Nullable(Of T) does is it adds a HasValue As Boolean property which allows you to check if the value is null. Therefore, when you go to read the value of the variable, rather than first checking to see if the variable Is Nothing, you need to instead check to see if it's HasValue property is true. For instance:
If dtIzvrsenja.HasValue Then
Dim dtIzvrsenja2 As Date = dtIzvrsenja.Value
' ...
End If
If you really want to treat the Date type as a real reference type, then you can do so by declaring the variable As Object. Object variables are always reference variables, so when set to Nothing, they really are set to null. When you set an Object variable to a value-type value, such as a Date, it will box the value. When you read it's value and convert it back to a Date, it will go through a process called unboxing. This boxing/unboxing process does add some overhead, however. Also, the other downside of this is that the type-checking for code working with the Object variable will be skipped at compile-time. That means that, if you are not careful, you could get some exceptions at runtime if the variable references a type of object that is different than what you expect. You could avoid the type-checking issue by declaring your own class:
Public Class DateReference
Public Property Value As Date
End Class
Or:
Public Class Reference(Of T)
Public Property Value As T
End Class
However, that seems silly. Nullable(Of T) already serves that purpose, so unless you really need to make it a reference type, I'd suggest that you take the time to get acquainted with the standard way of doing it.
As a side note, another complication which further causes confusion in this area is that VB's Nothing keyword does not strictly mean null. It just means the deafult value for any type. So, for an Integer, Nothing equals the value zero. For a Date, it means Date.MinValue, etc.

Answer 2

Use Nullable:
Dim nullableDateValue As New Nullable(Of Date) = Nothing

Answer 3

You can also use the question mark (Nullable) specifier, though this is probably outmoded now...
Dim dtIzvrsenja As DateTime? = Nothing