No Title Bar Issue and Windows 10 - vb.net

Question

I am developing an application with a custom title bar. The form design requires it to be resizable. Keeping in mind that it has a custom title bar, using the normal route to remove the title bar in the custom form is not working. It appears that the Windows 10 API is forcing a small white "chunk" to remain at the top of the screen above the title bar.
My question to you is this: Has anyone encountered this issue, and do you know a fix or a work-around so that we can get the forms to look correct in Windows 10?
Here is my current code:
Dim testform As New Form
testform.Width = 350
testform.Height = 100
testform.FormBorderStyle = FormBorderStyle.Sizable
testform.ControlBox = False
testform.Text = String.Empty
testform.Show()
We tested for the API issue due to a suggestion by another support forum that has since seemed to be exhausted as far as help. I compiled our existing code and ran the executable on a Windows 7 machine. On the Windows 7 machine the form opens properly with 0 space between the top of the ClientRectangle and the Form.

Answer 1

Here's an example of how to do (something) like what you want. My VB is really rusty, so make sure you test and debug this carefully.
First Add a Form to your project. For this example I've left the name Form1 but you probably want to change that to something meaningful. On that form I set the BorderStyle property to None. (That's the only change I made)
The code for Form1 is as follows:
Public Class Form1
Public Const WM_NCHITTEST As Integer = &H84
Public Const BorderSize As Integer = 10
Protected Overrides Sub WndProc(ByRef m As Message)
If m.Msg = WM_NCHITTEST Then
Dim x As Integer = m.LParam.ToInt32 And &HFFFF
Dim y As Integer = (m.LParam.ToInt32 >> 16) And &HFFFF
Dim p As Point = New Point(x, y)
If Me.Bounds.Contains(p) Then
Dim top As Boolean = Math.Abs(Me.Bounds.Y - y) < BorderSize
Dim bottom As Boolean = Math.Abs(Me.Bounds.Bottom - y) < BorderSize
Dim left As Boolean = Math.Abs(Me.Bounds.X - x) < BorderSize
Dim right As Boolean = Math.Abs(Me.Bounds.Right - x) < BorderSize
If top And left Then
m.Result = NCHITTEST.HTTOPLEFT
ElseIf top And right Then
m.Result = NCHITTEST.HTTOPRIGHT
ElseIf bottom And left Then
m.Result = NCHITTEST.HTBOTTOMLEFT
ElseIf bottom And right Then
m.Result = NCHITTEST.HTBOTTOMRIGHT
ElseIf top Then
m.Result = NCHITTEST.HTTOP
ElseIf bottom Then
m.Result = NCHITTEST.HTBOTTOM
ElseIf left Then
m.Result = NCHITTEST.HTLEFT
ElseIf right Then
m.Result = NCHITTEST.HTRIGHT
Else
m.Result = NCHITTEST.HTCAPTION
End If
Exit Sub
End If
End If
MyBase.WndProc(m)
End Sub
End Class
Additionally, somewhere in that makes sense in your project include the following enum. (I've stripped out the values I'm not using, but they are all available in the documentation) For the purposes of this demonstration I placed it directly beneath the End Class for Form1.
Public Enum NCHITTEST
HTBOTTOM = 15
HTBOTTOMLEFT = 16
HTBOTTOMRIGHT = 17
HTCAPTION = 2
HTLEFT = 10
HTRIGHT = 11
HTTOP = 12
HTTOPLEFT = 13
HTTOPRIGHT = 14
End Enum
The way it's implemented, there is an invisible 10px border where the mouse will change to the resize cursor. This is controlled by the BorderSize constant. You can move the form by clicking and dragging anywhere in the background. (That's what HTCAPTION does.)

Answer 2

TheB had the best answer, and I had to amend it slightly to work with my coding. Thank you for all of the help, sir!
So, when altering this code to work with a dynamically-created control a few changes needed to be made. Here is how I got it to work:
Create a new class specifically named: SubclassHWND.vb
(As gathered from Microsoft)
Public Class SubclassHWND
Inherits NativeWindow
Public Const WM_NCHITTEST = &H84
Public Const BorderSize As Integer = 10
Public frm As Form = Nothing
Public Sub setFrm(ByVal sender As Form)
frm = sender
End Sub
Protected Overloads Overrides Sub WndProc(ByRef m As Message)
if m.Msg = WM_NCHITTEST Then
Dim x As Integer = m.LParam.ToInt32 And &HFFFF
Dim y As Integer = (m.LParam.ToInt32 >> 16) And &HFFFF
Dim p As Point = New Point(x, y)
If frm.Bounds.Contains(p) Then
Dim top As Boolean = Math.Abs(frm.Bounds.Y - y) < BorderSize
Dim bottom As Boolean = Math.Abs(frm.Bounds.Bottom - y) < BorderSize
Dim left As Boolean = Math.Abs(frm.Bounds.X - x) < BorderSize
Dim right As Boolean = Math.Abs(frm.Bounds.Right - x) < BorderSize
If top And left Then
m.Result = NCHITTEST.HTTOPLEFT
ElseIf top And right Then
m.Result = NCHITTEST.HTTOPRIGHT
ElseIf bottom And left Then
m.Result = NCHITTEST.HTBOTTOMLEFT
ElseIf bottom And right Then
m.Result = NCHITTEST.HTBOTTOMRIGHT
ElseIf top Then
m.Result = NCHITTEST.HTTOP
ElseIf bottom Then
m.Result = NCHITTEST.HTBOTTOM
ElseIf left Then
m.Result = NCHITTEST.HTLEFT
ElseIf right Then
m.Result = NCHITTEST.HTRIGHT
Else
m.Result = NCHITTEST.HTCAPTION
End If
Exit Sub
End If
End If
Debug.WriteLine(m.ToString())
MyBase.WndProc(m)
End Sub
End Class
Public Enum NCHITTEST
HTBOTTOM = 15
HTBOTTOMLEFT = 16
HTBOTTOMRIGHT = 17
HTCAPTION = 2
HTLEFT = 10
HTRIGHT = 11
HTTOP = 12
HTTOPLEFT = 13
HTTOPRIGHT = 14
End Enum
This is basically the same exact code that #TheB supplied me with for the fix earlier with a couple of changes. We went ahead and created a new Public frm variable. We set this in the next set of code so we can reference the dynamic form that the WndProc evaluation will Override.
In the form generation code we added these lines to create the re-sizable window that has no title bar API in Windows 10:
newForm.FormBorderStyle = FormBorderStyle.FixedToolWindow
newForm.ControlBox = False
newForm.Text = String.Empty
Dim s As SubclassHWND = New SubclassHWND()
s.setFrm(newForm)
s.AssignHandle(newForm.Handle)
Now every dynamically-created form in the project uses the Overrides that we specified in SubclassHWND.vb! Thanks go out to everyone and all of their valuable input.