resize several sheets and save as PDF - vba

Question

I need do resize several sheets in order to get them always on the same size...and then save all of them as a PDF file. I do not know VBA so I'm doing a "frankestein code" getting pieces here and there.
What I get is the following code, that works for T1 sheet, but not for the other T2 and T3 sheets.How can I include them??
Sub Imprimir_PDF()
Dim ws As Worksheet
Dim lastRow As Long
Set ws = ThisWorkbook.Sheets("T1")
'find the last row with formatting, to be included in print range
lastRow = ws.UsedRange.SpecialCells(xlCellTypeLastCell).Row
ws.PageSetup.PrintArea = ws.Range("A2:CK" & lastRow).Address
ThisWorkbook.Sheets(Array("T1", "T2", "T3")).Select
Selection.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:="C:\PaintChecker\Camadas\temp.pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End Sub

Answer 1

This takes your code, and substitutes the part where you get the last Row with a short loop and set all three sheets print area in the loop.
Then prints all three out into the same PDF as is indicated by your select statement of the array.
untested:
Sub Imprimir_PDF()
Dim lastRow As Long
Dim count As Long
Dim sheet As String
'find the last row with formatting, to be included in print range
For count = 1 To 3
sheet = "T" & count
lastRow = Sheets(sheet).UsedRange.SpecialCells(xlCellTypeLastCell).row
Sheets(sheet).PageSetup.PrintArea = Sheets(sheet).Range("A2:CK" & lastRow).Address
Next count
ThisWorkbook.Sheets(Array("T1", "T2", "T3")).Select
Selection.ExportAsFixedFormat _
Type:=xlTypePDF, _
fileName:="C:\PaintChecker\Camadas\temp.pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
End Sub

Answer 2

Here's one way to do this:
Sub MakePDFs()
Dim sheetsToTouch As Variant
sheetsToTouch = Array("T1", "T2", "T3")
Dim sheetName As Variant
For Each sheetName In sheetsToTouch
Sheets(sheetName).Activate
ActiveSheet.PageSetup.PrintArea = ActiveSheet.Range("A2:CK" & ActiveSheet.UsedRange.SpecialCells(xlCellTypeLastCell).Row).Address
ActiveSheet.ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:="C:\PaintChecker\Camadas\" & sheetName & ".pdf", _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True
Next
End Sub