Multiple forms, instances and using them in a class. VB.net - vb.net-2010

Question

I have an MDI Parentform and it has multiple forms which are declared as :
Partial Public Class Giriş
Private clients As thirdperson
Private suppliers As thirdperson
Private activecontrol As thirdperson
Private proposals As transactions
Private addproposal As addtransaction
private sales as transactions
private addsales as addtransation
Private products As products
...
...
I also have a dataworks sub which works as a class but i code it in form and also for each form as below :
'for example for pressing add new button
If ActiveControl Is **clients** Or ActiveControl Is **suppliers** Then
activeform.dataworks (counter, "add new")
ElseIf ActiveControl Is products Then
products.dataworks (counter, "add new")
ElseIf ActiveControl Is addproposal Then
addproposal.dataworks (counter, "add new")
End If
i need a way to figure out how to use a vairble name for instance name. (I don't want to define each instance name everytime i just want to know if there is a way to use like below :
'for example
dim formvariable as form
formvariable.dataworks(counter,"add new") --> just want to use this and assign the value for products, proposals vs to this variable.
is this possible?
Thanks for your help in advance.
Sertac.

Answer 1

The proper way would be to develop an Interface that all of your Child Forms Implement. That interface would have a dataworks() method. Then you can cast the current mdichild to the interface type and run the method. This would result in strongly typed coded that makes sense.
If you just want to hack your way through it, though, then attempt grab the dataworks() sub from the current mdichild using reflection and execute it like below:
Dim frm As Form = Me.ActiveMdiChild
If Not IsNothing(frm) Then
Dim MI As Reflection.MethodInfo = frm.GetType.GetMethod("dataworks", Reflection.BindingFlags.Instance Or Reflection.BindingFlags.NonPublic Or Reflection.BindingFlags.Public Or Reflection.BindingFlags.IgnoreCase)
If Not IsNothing(MI) Then
MI.Invoke(frm, New Object() {counter, "add new"})
End If
End If
Here's a quick example of the Interface approach:
Public Interface Data
Sub DataWorks(ByVal counter As Integer, ByVal msg As String)
End Interface
This is what thirdperson looks like implementing the interface:
Public Class thirdperson
Implements Data
Public Sub DataWorks(counter As Integer, msg As String) Implements Data.DataWorks
Debug.Print(counter & ", " & msg)
End Sub
End Class
All of your mdichild forms would have to be modified in a similar approach.
Then the code in the MdiParent would change to:
Dim frm As Form = Me.ActiveMdiChild
If TypeOf frm Is Data Then
Dim D As Data = DirectCast(frm, Data)
D.DataWorks(counter, "add new")
End If