Applying multiple IF functions to every row - vba

Question

I need to apply the following IF functions to every row in columns J, L, and S so that the correct date value is printed in the corresponding cell in row T. For example, cell T2 will have a date printed in it based on the outcome of running these IF functions on J2, L2, and S2; cell T3 will have a date printed in it based on the outcome of running these IF functions on J3, L3, and S3; and so on. Here's what I have got:
Sub Test1()
Set firstDate = Range("S2")
If Range("J2") = "GS/CA/SL/GW" Then
If Range("L2") = "1" Or "2" Or "3" Then
Range("T2") = DateAdd("ww", 52, firstDate)
End If
If Range("L2") = "4" Or "5" Or "6" Then
Range("T2") = DateAdd("ww", 104, firstDate)
End If
If Range("L2") = "7" Or "8" Or "9" Then
Range("T2") = DateAdd("ww", 156, firstDate)
End If
End If
End Sub
It works on one set of cells at a time if I just redefine all the ranges, but I thought there must be an easier way than pasting and editing the code ~3500 times for all the rows I have to run it on. Any help would be appreciated!

Answer 1

If I follow your question correctly I believe you just need a simple loop to adapt your current code.
Try this:
Sub loopDate()
Application.ScreenUpdating = False
Dim LastRow As Integer
LastRow = Cells.Find(What:="*", After:=[A1], SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
Dim firstDate As Range
Dim i As Long
For i = 2 To LastRow
If Range("J" & i) = "GS/CA/SL/GW" Then
Set firstDate = Range("S" & i)
Select Case Range("L" & i)
Case 1 To 3
Range("T" & i) = DateAdd("ww", 52, firstDate)
Case 4 To 6
Range("T" & i) = DateAdd("ww", 104, firstDate)
Case 7 To 9
Range("T" & i) = DateAdd("ww", 156, firstDate)
End Select
End If
Next i
Application.ScreenUpdating = True
End Sub
Note that I started the loop at row 2 since that's what your example used and go until the last used row in column A. I also changed your if logic to a select case statement for improved readability.
You may want to just use an equation in cell T? instead of using VBA but since I don't know the details I'll assume you have a good reason.