Some SPARQL commands don't work when used in ISQL - sparql

Question

I have installed a local virtuoso server and imported dbpedia data into it. I found a range of SPARQL commands that don't work in isql. For example I ran this query in my isql shell.
SPARQL SELECT ?s GROUP_CONCAT (?obj, ' ') as ?artist_list WHERE { ?s a dbpedia-owl:Single ;(dbpedia-owl:artist|dbpedia-owl:producer) ?obj } limit 10
It first complains about the | in (dbpedia-owl:artist|dbpedia-owl:producer), then for the GROUP_CONCAT.
I did some research into Virtuoso docs and did the following
EDIT1
I tried to check different cases,
1- group_concat
SPARQL select ?s (group_concat(?obj; separator='|') as ?artist_list) FROM <http://ja.dbpedia.org> where { ?s a dbpedia-owl:Single ; (dbpedia-owl:artist) ?obj } group by ?s limit 10;
SQL> syntax error at 'group_concat' before '('
2- using values
SPARQL select ?s FROM <http://ja.dbpedia.org> where { values ?sType {dbpedia-owl:Song dbpedia-owl:Single }. ?s a ?sType} limit 10;
*** Error 37000: [Virtuoso Driver][Virtuoso Server]SQ074: Line 1: SP030: SPARQL compiler, line 1: syntax error at 'values' before '?sType'
3- using |
SPARQL select * FROM <http://ja.dbpedia.org> where { ?s (dbpedia-owl:artist|dbpedia-owl:producer) ?o } limit 10
*** Error 37000: [Virtuoso Driver][Virtuoso Server]SQ074: Line 1: SP030: SPARQL compiler, line 0: Invalid character in SPARQL expression at '|'
What am I doing wrong? All above SPARQL queries work in Standard SPARQL endpoints

Answer 1

I don't think that Virtuoso supports all of SPARQL 1.1, but your query isn't legal SPARQL either. (Virtuoso does accept some stuff that's not quite SPARQL, but your query is within the realm of SPARQL.) I suggest you take a look at sparql.org's query validator. You'll find at least the following issues:
You didn't define the dbpedia-owl: prefix. (You might have that in the endpoint though, so it might not be a problem.)
It needs to be (group_concat(…) as …) with parenthesis. (The case doesn't matter, though, so GROUP_CONCAT is fine. I think Virtuoso will accept it without the parens, but that doesn't make it legal SPARQL.)
In group_concat, you need to use a semicolon and write separator.
If you're using aggregates like group_concat, then you're grouping by some variables, and you can't select a variable that you're not grouping by. That means that you need to group by ?s.
Once you fix those things, you'd end up with something like:
prefix dbpedia-owl: <http://dbpedia.org/ontology/>
select ?s (group_concat(?obj; separator=' ') as ?artist_list)
where {
?s a dbpedia-owl:Single ;
(dbpedia-owl:artist|dbpedia-owl:producer) ?obj
}
group by ?s
limit 10
That's legal SPARQL 1.1. If Virtuoso still complains about that, you could use a values block instead of the property path, and so have the following, which is equivalent:
prefix dbpedia-owl: <http://dbpedia.org/ontology/>
select ?s (group_concat(?obj; separator=' ') as ?artist_list)
where {
values ?p { dbpedia-owl:artist dbpedia-owl:producer }
?s a dbpedia-owl:Single ;
?p ?obj
}
group by ?s
limit 10
If you still get complaints about values (but DBpedia's endpoint supports values, and it's Virtuoso; how old a version are you installing?), you can use union:
prefix dbpedia-owl: <http://dbpedia.org/ontology/>
select ?s (group_concat(?obj; separator=' ') as ?artist_list)
where {
?s a dbpedia-owl:Single .
{ ?s dbpedia-owl:artist ?obj } UNION
{ ?s dbpedia-owl:producer ?obj }
}
group by ?s
limit 10
If you want some SPARQL 1.1 support, you'll need to use at least Virtuoso 7.0.0. The release notes include:
2013-08-05 -- Virtuoso Open-Source Edition 7.0.0 Released
Added support for SPARQL 1.1 BIND and VALUES clauses
Added support for SPARQL 1.1 Functions and Aggregates
Added support for ?graph parameter in SPARQL 1.1 Graph Protocol
Fixed issues with Transitivity, Inference, and SPARQL 1.1 Property Paths