How to refer to VBProject in a different xlsm Workbook? - vba

Question

I need to write a macro that will create a new workbook test.xlsm and assign a vb code to it's first sheet (Sheet1).
Sub AddCode()
Dim wb As Workbook
Set wb = Workbooks.Add
Dim ws As Worksheet
Set ws = wb.Worksheets(1)
Dim code As String
code = "Sub test()" & vbCrLf & MsgBox "Test" & vbCrLf & "End Sub"
Dim lineCount As Integer
With wb.VBProject.VBComponents(ws.Name).CodeModule
lineCount = .CountOfLines
If lineCount > 0 Then
.DeleteLines 1, lineCount
End If
.AddFromString code
End With
wb.Save FileName:="C:\Users\Owner\Desktop\test.xlsm", FileFormat:=52
wb.Close
End Sub
I get subscript out of range error . I presume that I am referring to the wrong vb project
(PS: by "assigning a code to it's first sheet" I mean the following: Right Click on the Sheet1 -> View Code -> Paste my code to the Module )

Answer 1

You can save your workbook as an add-in and then load it into excel. Then you can add a reference to the add-in from the VBE editor and access the functions/subs.
You can google Chip Pearson's tutorials, and other such material for such stuff. Here is where he explains how you can manipulate the Visual Basic Editor to programmatically add code, etc. Possibly useful in your case.
Ref: http://www.cpearson.com/Excel/VBE.aspx
Just for ease of reference (all from the above website by Chip Pearson)
Adding A Module to a Project:
Sub AddModuleToProject()
Dim VBProj As VBIDE.VBProject
Dim VBComp As VBIDE.VBComponent
Set VBProj = ActiveWorkbook.VBProject
Set VBComp = VBProj.VBComponents.Add(vbext_ct_StdModule)
VBComp.Name = "NewModule"
End Sub
and most importantly, adding a Subroutine to a Module:
Sub AddProcedureToModule()
Dim VBProj As VBIDE.VBProject
Dim VBComp As VBIDE.VBComponent
Dim CodeMod As VBIDE.CodeModule
Dim LineNum As Long
Const DQUOTE = """" ' one " character
Set VBProj = ActiveWorkbook.VBProject
Set VBComp = VBProj.VBComponents("Module1")
Set CodeMod = VBComp.CodeModule
With CodeMod
LineNum = .CountOfLines + 1
.InsertLines LineNum, "Public Sub SayHello()"
LineNum = LineNum + 1
.InsertLines LineNum, " MsgBox " & DQUOTE & "Hello World" & DQUOTE
LineNum = LineNum + 1
.InsertLines LineNum, "End Sub"
End With
End Sub
Another way is simply to do the following
Dim FileNameStr as String, Path as String
' Set these two to the correct strings
Dim wb as Workbook
set wb = workbooks.open(Path & "\" & FileNameString)
Application.Run (wb.Name & "!NameOfYourMacro")
This way you can run a macro without arguments
Of course that's just the core of the code. You still need to clean up afterwards, close workbooks, maybe set them as readonly when opening, etc. but you get the drift.