Select and Remove Characters - vba

Question

I'm trying to remove remove the string that the user enter and the next 16 characters after this string... When I'm removing just the string that I enter, it's working, but when I ask to remove the others next 16 characters it's stop to work. Could some one help me?
The file is:
04_03(+16 characters) text 04_03(+16characters)
04_03(+16 characters) text 04_03(+16characters) text 04_03(+16characters)
text 04_03(+16characters)
The user enters:
strSearch = 04_03
I would like to delete the string 04_03 more the next 16 characters after this string, independetly which characters they are from the file.
The final file should be:
text
text text
text
Global strSearch As String
Global strLenght As Double
Function RegExpReplace(ByVal WhichString As String, _
ByVal pattern As String, _
ByVal ReplaceWith As String, _
Optional ByVal IsGlobal As Boolean = True, _
Optional ByVal IsCaseSensitive As Boolean = True) As String
'Declaring the object
Dim objRegExp As Object
'Initializing an Instance
Set objRegExp = CreateObject("vbscript.regexp")
'Setting the Properties
objRegExp.Global = IsGlobal
objRegExp.pattern = pattern
objRegExp.IgnoreCase = Not IsCaseSensitive
'Execute the Replace Method
RegExpReplace = objRegExp.Replace(WhichString, ReplaceWith)
End Function
Sub findCharacter()
strSearch = InputBox("How starts the text that you would like to remove?", "Character's Search")
If strSearch = "" Then Exit Sub
End Sub
Sub RemoveCharacters()
Dim pattern As String
Dim str As String
Dim u As String
With Sheets("Sheet1")
.Select
Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row
For Lrow = 1 To Lastrow Step 1
str = Cells(Lrow, 1).Value
pattern = strSearch + " [\w \W \s] {16}"
Cells(Lrow, 1).Value = RegExpReplace(str, pattern, "")
Next Lrow
End With
End Sub

Answer 1

Is this what you are trying?
Option Explicit
Sub Sample()
Dim ws As Worksheet
Dim lRow As Long, pos As Long, i As Long, n As Long
Dim strToRepl As String, strSearch As String
strSearch = InputBox("How does the text start that you would like to remove?", "Character's Search")
If strSearch = "" Then Exit Sub
'~~> Change this to the relevant sheet
Set ws = ThisWorkbook.Sheets("Sheet1")
With ws
lRow = .Range("A" & .Rows.Count).End(xlUp).Row
For i = 1 To lRow
pos = InStr(1, .Range("A" & i).Value, strSearch, vbTextCompare)
If pos > 0 Then
n = Len(.Range("A" & i).Value) - pos
If Not Len(strSearch) + 16 > n Then
strToRepl = Mid(.Range("A" & i).Value, pos, Len(strSearch) + 16)
.Range("A" & i).Value = Replace(.Range("A" & i).Value, strToRepl, "")
End If
End If
Next i
End With
End Sub
Screenshot