Numbering my cells and resetting based on year - vba

Question

This is my first post to stack overflow and my first online question about programming.
I am developing a program to record requests for projects (Work Orders) in a manufacturing plant. The current system is being removed due to the switch from Windows XP.
I am having trouble developing my numbering code.
The format of the code is:
YY - ######. I'm currently using:
.Cells(iRow, 1).Value = Format(Date, "yy") & " - " & Format(iRow - 1, "000000")
So that would input the Year and the "iRow" - 1 into the first column. iRow is determined using:
iRow = 2 'starting index for next empty WONum cell
With WORecordSheet
'Find the next empty WONum cell
Do While .Cells(iRow, 1).Value <> ""
.Cells(iRow, 1).Activate
iRow = iRow + 1
Loop
End With
It loops through each until an empty row is found, then inputs the number using the year and that specified row minus one into that cell.
The problem I'm having is with the year. When a new year comes, it needs to switch back to the first work order.... Such as:
14 - 001111
14 - 001112
14 - 001113
15 - 000001
15 - 000002
But, the problem is that the number is made using the row, so it won't restart with a new year. I know that I will need another variable that either adds 1 to the previous number if the year is the same or loops through just the rows of the same year until a new row is found and that is the number put in for the work order number, but the empty row to input the number into should be decided the same way as before, with the iRow loop.
I do not know how I could determine the year of the previous entry... Could you somehow separate the value into the two parts of "YY" and "######"? And run an if statement that if the "YY" is the same as the current year then it adds 1 to the "######"?
Thanks for any suggestions!
UPDATE: I have created a block of code that works. It is based off of the response from #user1759942 . However, I did reference the other responses to dim variables and use the "Right" function properly. Here is the updated code:
Dim iRow As Long
Dim yr As Long
Dim lCodeNum As Long
WORecordSheet.Activate
iRow = 2 'starting index for next empty WONum cell
lCodeNum = 1 'starting index for last 6 digits of wonum
With WORecordSheet
'Find the next empty WONum cell
Do While .Cells(iRow, 1).Value <> ""
.Cells(iRow, 1).Activate
iRow = iRow + 1
Loop
yr = Left(.Cells(iRow - 1, 1).Value, 2)
If yr = Format(Date, "yy") Then
lCodeNum = Right(.Cells(iRow - 1, 1).Value, 6) + 1
Else
lCodeNum = 1
End If
End With
And later on:
.Cells(iRow, 1).Value = Format(Date, "yy") & " - " & Format(lCodeNum, "000000")

Answer 1

you can do exactly what you thought. Separate the YY from the rest and examine that.
have a variable - dim yr as string to save the year, and I'd use a separate variable for putting the number: dim lCodeNum as long and in the while loop set those variables too
dim yr as string
iRow = 2 'starting index for next empty WONum cell
lCodeNum = 1
With WORecordSheet
'Find the next empty WONum cell
yr = left(.cells(iRow,1).value, 2) 'gets the first 2 characters in the cell
Do While .Cells(iRow, 1).Value <> ""
.Cells(iRow, 1).Activate
iRow = iRow + 1
if not left(.cells(iRow, 1).value, 2) = yr then
lCodeNum = 1
else
lCodeNum = lCodeNum + 1
end if
yr = left(.cells(iRow,1).value, 2)
Loop
End With
then when you assign the value to the empty cell you can do:
.Cells(iRow, 1).Value = Format(Date, "yy") & " - " & Format(lCodeNum, "000000")
so the way above, you're using irow to loop over every row, and to reference the cells, but using lCodeNum as the number, thus it resets to 1 every time a new year is encountered.
you could use irow instead of lcodenum, but then you could only put 1 if a new year was encountered, and then the numbers would pick up where they left off, so you'd end up with like
14 - 000144
14 - 000145
15 - 000001
15 - 000147

Answer 2

This isn't a 100% complete answer, but hopefully it will give you everything you need to apply it to your own program. Also, this isn't the only way to address this, but it is one way. Hopefully it will give you a good enough nudge in the right direction...
It's simple enough to get the last two digits of the current year in VBA doing something like:
Dim yearDigits As Long
yearDigits = Right(Year(Now), 2)
now that you know the current year's last 2 digits, you can compare it to the some data string like YY - ###### by doing something close to:
Dim invoice As String
yearDigits = Right(year(Now), 2)
invoice = "13 - 001111"
invoiceYear = Left(invoice, 2)
tying it together may look something like:
Sub test()
Dim yearDigits As Long
Dim invoice As String
Dim invoiceYear As Long
Dim equalYear As Boolean
yearDigits = Right(year(Now), 2)
invoice = "13 - 001111"
invoiceYear = Left(invoice, 2)
equalYear = yearDigits = invoiceYear
MsgBox "Current Year = " & yearDigits & ". Invoice Year = " & invoiceYear & ". Are they equal? " & equalYear
End Sub
If this doesn't help, or you need some help applying it to your code, please post back and I'll give you some more nudges.
Good luck!

Answer 3

This should place a new number code in column A each time it is run. It should re-start the sequencing on change of year:
Sub FillId()
Dim N As Long, Prev As String, PrevYr As Long, PrevNum As Long
Dim Yr As Long, M As Long
If Range("A1").Value = "" Then
Range("A1").Value = Mid(Year(Date), 3) & " - " & "000001"
Exit Sub
End If
N = Cells(Rows.Count, "A").End(xlUp).Row
Prev = Cells(N, "A").Value
PrevYr = CLng(Mid(Prev, 1, 2))
PrevNum = CLng(Mid(Prev, 6))
Yr = CLng(Mid(Year(Date), 3))
If Yr <> PrevYr Then
M = 1
Else
M = PrevNum + 1
End If
Cells(N + 1, "A").Value = Mid(Year(Date), 3) & " - " & Format(M, "000000")
End Sub