Can you give columns in Excel a variable name? - vba

Question

I have a fairly large Excel spreadsheet, there are around 4500 rows with 35 columns.
Our VBA code references columns by their letter (aka A1, A2, A3 ... A4500) when modifying field values ... this is a limitation as we are unable to move columns around within our sheet without having to update all of our code to where that column has moved to.
Is it possible to give a column a variable name?
If column A currently holds First Name, is it possible to name this column First_Name so that regardless of where this column moves, it retains the First_Name reference?
Then in our VBA code we can say First Name instead of A1?
Thanks!

Answer 1

The easiest way is to dimension (35) variables or Enums that correspond to the either columns or column numbers.
Option Explicit
Public Const Name As String = "A"
Public Const Age As String = "C"
Public Const ID As String = "F"
...
then when referring to the columns use the defined names ie. Range(Name & 13).
this way you only ever need to modify the public constants when the order of column changes.
if you reference columns by numbers consider using Enum
Public Enum Col
Name = 1
ID = 2
Age = 3
End Enum
Sub Main()
Cells(1, Col.ID) = "ID HEADER"
End Sub

Answer 2

Here's a version that dynamically finds the column:
Sub test()
Do While True ' Ctrl-Break to stop
MsgBox ColByName(InputBox("Name:"))
Loop
End Sub
Function ColByName(colName As String) As Long
Dim iCol As Long
For iCol = 1 To UsedRange.Columns.Count ' need better upper range for code off of a sheet
If Cells(1, iCol) = colName Then
ColByName = iCol
Exit Function
End If
Next iCol
ColByName = -1
End Function
I prefer the ENum route but sometimes it is just not practical and it can introduce maintenance issues.
An alternate approach is a collection indexed by name - rebuild the collection when the columns are moved etc. Note that the test shows the default compare is case sensitive.

Answer 3

A technique I use frequently is to leverage an Excel table. Using this command will create a special object within your worksheet that you can then reference within your VBA code. (You can, of course, add a new Excel table programatically using VBA if you like.)
For example, if you have a data in your worksheet like:
+--------------+-------------+
| First_Name | Last_Name |
+--------------+-------------+
| John | Smith |
| Sally | Jones |
+--------------+-------------+
Once you convert it into an Excel table, you will be able to reference it using code like:
Option Explicit
Public Sub SampleCode()
'
' selects Last_Name column
'
Range("Table1[Last_Name]").Select
'
' prints "Jones"
'
Debug.Print Cells(3, Range("Table1[Last_Name]").Column).Value
End Sub
Excel will create a sequential table name for your starting with Table1. You can change this name within Excel or give it a unique name if you create it programmatically.