Looping through Word document to format text - vba

Question

I have a huge document in which the lines starting with some specific words text style should be changed. I have created an array for all those words and tried formatting the document using For loop. But only the style of first word in the array is getting changed not for all the words in the array.
Below is what I did, please have a look at it and suggest the solution:
Sub Variables_NormalTxt()
Dim oRng As Word.Range
Dim oRngFC As Word.Range
Dim varUbyteNormal As Variant
Dim ArrayItem As String
Dim i As Integer
varUbyteNormal = Array("uword", "ubyte", "bool", "sword", "const", "ulong", "static")
Set oRng = ActiveDocument.Range
i = 0
For i = 0 To UBound(varUbyteNormal)
With oRng.Find
.Text = varUbyteNormal(i)
.Font.Name = "Times New Roman"
.Font.Bold = False
.Font.size = 10
While .Execute
oRng.Select
Set oRngFC = ActiveDocument.Bookmarks("\Line").Range
oRngFC.Style = "variable normal"
Wend
End With
Next i
End Sub

Answer 1

Move this line
Set oRng = ActiveDocument.Range
into the For loop
i.e.
For i = 0 To UBound(varUbyteNormal)
Set oRng = ActiveDocument.Range
With oRng.Find
etc.
Incidentally...
You can remove the line
i = 0
Your For statement can be generalised to
For i = LBound(varUbyteNormal) To UBound(varUbyteNormal)
and perhaps others will suggest other improvements.
( ...a further look suggests the following, but it depends on precisley
what you are looking for)
Sub Variables_NormalTxt3()
Dim oRng As Word.Range
Dim varUbyteNormal As Variant
Dim ArrayItem As String
Dim i As Integer
varUbyteNormal = Array("uword", "ubyte", "bool", "sword", "const", "ulong", "static")
For i = LBound(varUbyteNormal) To UBound(varUbyteNormal)
Set oRng = ActiveDocument.Range
With oRng.Find
.ClearAllFuzzyOptions
.ClearFormatting
.Text = varUbyteNormal(i)
.Font.Name = "Times New Roman"
.Font.Bold = False
.Font.Size = 10
' perhaps also...
.MatchCase = False
While .Execute
oRng.Style = "variable normal"
Wend
End With
Set oRng = Nothing
Next 'i
End Sub

Answer 2

Dim varUbyteNormal As Variant
varUbyteNormal = Array("uword", "ubyte", "bool", "sword", "const", "ulong", "static")
Dim i As Long
For i = LBound(varUbyteNormal) To UBound(varUbyteNormal)
With ActiveDocument.Range.Find
.ClearFormatting
.ClearAllFuzzyOptions
With .Font
.Name = "Times New Roman"
.Bold = False
.Size = 10
End With
.Text = varUbyteNormal(i)
With .Replacement
.ClearFormatting
.Style = "variable normal"
End With
.Execute Replace:=wdReplaceAll
End With
Next