Add shared library to cpack - cmake

Question

How could I add a shared libraray (Qt6Core.dll) to CPack? I tested the following snipped:
set(MY_DEPENDENCY_PATHS "C:/Qt/6.0.0/msvc2019_64/bin/")
install(CODE "set(MY_DEPENDENCY_PATHS \"${MY_DEPENDENCY_PATHS}\")")
install(CODE [[
file(GET_RUNTIME_DEPENDENCIES
LIBRARIES $<TARGET_FILE:Qt6::Core>
RESOLVED_DEPENDENCIES_VAR _r_deps
UNRESOLVED_DEPENDENCIES_VAR _u_deps
DIRECTORIES ${MY_DEPENDENCY_PATHS}
)
foreach(_file ${_r_deps})
file(INSTALL
DESTINATION "${CMAKE_INSTALL_PREFIX}/lib"
TYPE SHARED_LIBRARY
FILES "${_file}"
)
endforeach()
list(LENGTH _u_deps _u_length)
if("${_u_length}" GREATER 0)
message("Anzahl: ${_u_length}")
message(WARNING "Unresolved dependencies detected!")
endif()
]])
But it shows me:
CMake Warning at C:/CPP/Projects/beans/build/packaging/cmake_install.cmake:89 (message):
Unresolved dependencies detected!
Call Stack (most recent call first):
C:/CPP/Projects/beans/build/cmake_install.cmake:57 (include)
Now are over 200 other shared libraries in my /lib directory but no Qt6Core.dll.

Answer 1

I solved my Problem.
set(MY_DEPENDENCY_PATHS "C:/Qt/6.0.0/msvc2019_64/bin/")
install(CODE "set(MY_DEPENDENCY_PATHS \"${MY_DEPENDENCY_PATHS}\")")
install(CODE [[
file(GET_RUNTIME_DEPENDENCIES
LIBRARIES $<TARGET_FILE:MYPROJECT>
RESOLVED_DEPENDENCIES_VAR _r_deps
UNRESOLVED_DEPENDENCIES_VAR _u_deps
DIRECTORIES ${MY_DEPENDENCY_PATHS}
PRE_EXCLUDE_REGEXES "api-ms-" "ext-ms-"
POST_EXCLUDE_REGEXES ".*system32/.*\\.dll"
)
foreach(_file ${_r_deps})
file(INSTALL
DESTINATION "${CMAKE_INSTALL_PREFIX}/lib"
TYPE SHARED_LIBRARY
FILES "${_file}"
)
endforeach()
list(LENGTH _u_deps _u_length)
if("${_u_length}" GREATER 0)
message(WARNING "Unresolved dependencies detected!")
endif()
]])