Flag observations that fulfill two conditions together - sql

Question

I am very new to SAS as well as SQL and would appreciate help.
I have a data set containing student id, term and audit_type. Each term has 2 audit_types and the student can be present at either of them or be present at both.
I need to create a flag for each of these 3 scenarios for each student id each term: 1) if the student is present at only audit_type_1, 2) if s/he is present at only audit_type_2 and 3) if s/he is present at audit_type_1 and audit_type_2 both during that term. Not sure how to post my data but here it is
Sample data
| Id | Term | Audit_type |
|---- |------------- |-----------: |
| 1 | Fall 2016 | 1 |
| 1 | Fall 2016 | 2 |
| 2 | Winter 2017 | 1 |
| 3 | Winter 2017 | 2 |
| 4 | Spring 2017 | 1 |
| 4 | Spring 2017 | 2 |
I was able to create a flag for the first 2 scenarios using case when as seen below:
proc sql;
create table test as
select id, term, audit_type,
case
when audit_type in ('audit_type_1') then 1
when audit_type in ('audit_type_2 ') then 2
end as audit_type_flag
from have;
I can't figure out how to flag the third scenario. All help will be highly appreciated. Thanks in advance for your help and support. So, I want something like below:
| Id | Term | Audit_type | Flag |
|---- |------------- |-----------: |------ |
| 1 | Fall 2016 | 1 | 3 |
| 1 | Fall 2016 | 2 | 3 |
| 2 | Winter 2017 | 1 | 1 |
| 3 | Winter 2017 | 2 | 2 |
| 4 | Spring 2017 | 1 | 3 |
| 4 | Spring 2017 | 2 | 3 |

Answer 1

I am sort of reading between the lines here and assumed that you are using the logic Audit_Type = 1 then Flag = 1, Audit_Type = 2 then Flag = 2, if it is both then 3 so I just added the flags together and gained 3. This may not be what you are after (you may want a 4, 5, 6 and 7 flag as well), it was just an assumption based on a small amount of data and not knowing the exact use case, therefore, I will provide a solution and if it is correct please let me know and I will add comments explaining the syntax. I don't want to spend time explaining the code if it isn't precisely what you are looking for.
Regards,
Scott
UPDATE
I have added the comments to the code as well as links to pages which may help you better understand what I am talking about.
/* SETUP SOME DUMMY DATA */
DATA HAVE;
LENGTH ID 3. TERM $11. AUDIT_TYPE 3.;
INFILE DATALINES DSD DELIMITER = "," missover;
INPUT ID TERM AUDIT_TYPE;
DATALINES;
1,Fall 2016,1
1,Fall 2016,2
1,Summer 2016,1
1,Summer 2016,2
2,Winter 2017,1
3,Winter 2017,2
4,Spring 2017,1
4,Spring 2017,2
;
RUN;
/* PERFORM A SORT SO THAT WE CAN MAKE USE OF BY STATEMENT PROCESSING IN THE
SUBSEQUENT DATA STEP */
PROC SORT DATA = HAVE;
BY ID TERM;
RUN;
DATA WANT;
/* DOW LOOP */
/* THIS LOOP EXECUTES FOR EACH ROW UNTIL THE LAST.TERM IS ENCOUNTERED. */
/* COMMENTING OUT THE SECOND DOW LOOP WILL SHOW YOU THAT THIS LOOP IS
BASICALLY SUMMARISING THE RESULT OF EACH ID, TERM GROUP AFTER THE CONDITIONAL
LOGIC IS APPLIED TO THE FLAG VARIABLE.*/
DO UNTIL (LAST.TERM);
/* EACH TIME THE DO LOOP EXECUTES A NEW ROW IS READ INTO THE PDV (PROGRAM DATA VECTOR).*/
SET HAVE;
/* THE BY STATEMENT IS IN PLACE TO FACILITATE BY STATEMENT PROCESSING. */
BY ID TERM;
/* INITIALISE THE FLAG VARIABLE EACH TIME A NEW TERM IS ENCOUNTERED */
IF FIRST.TERM THEN FLAG = 0;
/* USING THE SYNTAX FLAG + 1 REPLICATES USING THE RETAIN STATEMENT WITH A SUM FUNCTION.
IT IS REFERRED TO AS THE SUM STATEMENT. IF YOU ARE INTERESTED IN LEARNING MORE ABOUT
THIS THEN SEE THE LINK TO THE DOCUMENTATION BELOW.*/
IF AUDIT_TYPE = 1 THEN FLAG + 1;
ELSE IF AUDIT_TYPE = 2 THEN FLAG + 2;
END;
/* ONCE THE PREVIOUS DOW LOOP EXITS (BECAUSE THE LAST.TERM HAS BEEN REACHED) THE SECOND
DOW LOOP EXECUTES*/
DO UNTIL (LAST.TERM);
/* AS PER DOW LOOP 1, EACH LOOP RESULTS IN A SINGLE OBSERVATION BEING READ */
SET HAVE;
/* THE BY STATEMENT IS IN PLACE TO FACILITATE BY STATEMENT PROCESSING. */
BY ID TERM;
/* THE EXPLICIT OUTPUT STATEMENT EXECUTES TO OUTPUT THE VALUES CONTAINED WITHIN THE
PDV */
OUTPUT;
END;
RUN;
Further reading:
The DOW-loop: a Smarter Approach to your Existing Code
The Sum Statement
The Power of the BY Statement

Answer 2

just use additional else with case it will be solved
select id, term, audit_type,
case
when audit_type in ('audit_type_1') then 1
when audit_type in ('audit_type_2 ') then 2
else 3
end as audit_type_flag
from have;

Answer 3

I think you need aggregation:
proc sql;
create table test as
select id, term, audit_type,
(case when min(audit_type) <> max(audit_type) then 1
when min(audit_type) = 2 then 2
when min(audit_type) = 3 then 3
end) as audit_type_flag
from have
group by id, term;