Send file, with images which are stored internally, to external recipients - vba

Question

I send a file with images to clients. When the client opens the file all the images are gone or there is an error message. This document is updated weekly with new inventory data.
All images reference column E and images are saved to a folder within the company server.
The code I have been using is:
Sub IMAGEINSERT()
Dim pictureNameColumn As String 'column where picture name is found
Dim picturePasteColumn As String 'column where picture is to be pasted
Dim pictureName As String 'picture name
Dim lastPictureRow As Long 'last row in use where picture names are
Dim pictureRow As Long 'current picture row to be processed
Dim pathForPicture As String 'path of pictures
pictureNameColumn = "E"
picturePasteColumn = "A"
pictureRow = 2 'starts from this row
'error handler
On Error GoTo Err_Handler
'find row of the last cell in use in the column where picture names are
lastPictureRow = Cells(Rows.Count, pictureNameColumn).End(xlUp).Row
'stop screen updates while macro is running
Application.ScreenUpdating = False
pathForPicture = "M:\Sales\Accessories\Hope G\_OFF PRICE\_ATS REPORTS\ATS LIST\images\"
'loop till last row
Do While (pictureRow <= lastPictureRow)
pictureName = Cells(pictureRow, "E") 'This is the picture name
'if picture name is not blank then
If (pictureName <> vbNullString) Then
'check if pic is present
If (Dir(pathForPicture & pictureName & ".jpg") <> vbNullString) Then
'This is where picture will be inserted
Cells(pictureRow, picturePasteColumn).Select
'Path to where pictures are stored
ActiveSheet.Pictures.Insert(pathForPicture & pictureName & ".jpg").Select
With Selection
.Left = Cells(pictureRow, picturePasteColumn).Left
.Top = Cells(pictureRow, picturePasteColumn).Top
.ShapeRange.LockAspectRatio = msoFalse
.ShapeRange.Height = 80#
.ShapeRange.Width = 60#
.ShapeRange.Rotation = 0#
End With
Else
'picture name was there, but no such picture
Cells(pictureRow, picturePasteColumn) = ""
End If
Else
'picture name cell was blank
End If
'increment row count
pictureRow = pictureRow + 1
Loop
Exit_Sub:
Range("A10").Select
Application.ScreenUpdating = True
Exit Sub
Err_Handler:
MsgBox "Error encountered. " & Err.Description, vbCritical, "Error"
GoTo Exit_Sub
End Sub

Answer 1

I'm assuming that the clients you're sending the file to are external clients.
The Pictures.Insert method only creates a link to the picture, so external clients which don't have access to your company server won't be able to see the pictures.
You need to instead use the Shapes.AddPicture method, which can embed the picture in the file.
Activesheet.Shapes.AddPicture Filename:=pathForPicture & pictureName & ".jpg", _
LinkToFile:=msoFalse, SaveWithDocument:=msoTrue, _
Left:=Selection.Left, Top:=Selection.Top, Width:=-1, Height:=-1
Note that the Width and Height parameters are mandatory, but you can set them to -1, which then maintains the height and width of the original image!